sys-kernel/gentoo-kernel-bin: bump to 5.10.23 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 3c0981765c35..450d37d28285 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -53,6 +53,7 @@ DIST gentoo-kernel-5.10.22-1.amd64.xpak 64085208 BLAKE2B 2ad4a5ac3391bf34c15a190
 DIST gentoo-kernel-5.10.22-1.arm64.xpak 59289046 BLAKE2B fdacceeb2cc5078438f65f6ef5a30669a3c5f20d66c68578265574af56afcf810625d321f6ee889fb31ac6e2ee6a9e92256dfde8d22364747667c94dc0d1e1b5 SHA512 e0af4c4e921621a342b901e2b8e1c2ca19817d5f412a106d2718afc8c967163a2068056cb29b0c8ae739bf77d29277a2fb493c028ca4477af59b68fff79e63da
 DIST gentoo-kernel-5.10.22-1.x86.xpak 57048115 BLAKE2B a07ef32fa35da33d9b5d56c66c18465e3ae89edb801763e87a2de543fdaa37722e063f64da42074baf42f26b990dfbf9e1e7d102943dc5edf791727d568d776f SHA512 f9f85ac08c1ca19715ecda74242ceaee600e2ae83aa6dfe5fa862dfceecfb0d1f16bdebbeb96bbf706555e717e4200a7de705017b62788f74bc16561d2372ac6
 DIST gentoo-kernel-5.10.23-1.amd64.xpak 64099761 BLAKE2B 68a9947ade38ee341527109c247e912693d3eab2c7df951ec811ef650709100672f2f839f142e35bb51225de327e22160d646a361df34edc7ce5dca6839575d4 SHA512 97b22fa157a093e0c0313dec79c9eaa68e794791b2a26bbd41b39ea89a93cbdaa9af61084d2cb5f48d0c86612c5093b7650884aac6668f599ddebdb2da00d937
+DIST gentoo-kernel-5.10.23-1.arm64.xpak 59366782 BLAKE2B 492c537807abf949818ff306096dc3b07e34c9406c4ecf56c34334c6c14d80fb5183fc95ea942d9a511800a0b6c3ae260405b1d8209585cbf6199b5e639a5987 SHA512 d28ca649f912a95ad997916707f2555c1552dca9b0abecae3ff0a8c6fb7daf08c996656e7b6489b1e7541a14d6a45bf05dde1b1302adea1da7f1cd0b0e19eb3e
 DIST gentoo-kernel-5.10.23-1.x86.xpak 57061009 BLAKE2B 6c8c05b418a6abdca512ee68af83c3dc7fb4e117b093cf228d90c1ac57c404983d4a0b8bc69c89d5e03087ac68ad2ae9d342fbaa9e1bebf150db4d169900f23d SHA512 24b155a996f36aeabffae4445ae6bfea2a665cfd149cc2fae95dae27b4e971775ac9b054ad2935c3932b1064e219a4594ebdeb3c441740fde09f3371d6f4c112
 DIST gentoo-kernel-5.10.24-1.amd64.xpak 64100066 BLAKE2B 0f18bedb448c5c0bd8165846a190278b9a96264b04a09be97fc51968fd74f66f29ea7ff845ac874748c1ac60c4c4a4aa4a72d7a273e84551fe09d870715407b9 SHA512 414a12ae14da6a81dd0dbdf80f05e511d686bdba7f5fffe5c754144f7dd9245368ee3a1673df16e996e80985b7f435613d888c5e5324d967dd622b9db03407fc
 DIST gentoo-kernel-5.10.24-1.x86.xpak 57056253 BLAKE2B 5925e7739cda2fd853d919a4681f28849afb9552acfd7cb91387828d6c7286ce9b1b32b93e55339311696e5bf62974a2a117c668221fca3ec062bf574569837f SHA512 395019c3a8d40eea18d92db2507386bd2202a8f13e25bb7a247724820a8f0ee854a05c6e999129556e894443b011928e80fa41612bef6a6c070035ecf11c749f
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.23-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.23-r1.ebuild
new file mode 100644
index 000000000000..18c02d4c0f39
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.23-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${PV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"usr/src/linux-${PV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${PV}"/ || die
+}