sys-kernel/gentoo-kernel-bin: bump to 5.4.141-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 747e39544c92..fa1bfdb45eb9 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -129,6 +129,7 @@ DIST gentoo-kernel-5.4.140-1.amd64.xpak 61369693 BLAKE2B 5f869206ad8102cca2e6cc7
 DIST gentoo-kernel-5.4.140-1.arm64.xpak 57965446 BLAKE2B 560b269104ff385823bfe067483d44440c6cc3bce3e41b1a156316e9af57b9bd9a2d1fcc8f7b698a330bde5c926e2c0e6f61d372085e79aee02e97295b1c7cbf SHA512 74c346964e6b21cd1073140b4e0559ba2fd166a73696d091d09c8656ce95c08f89662a70344deb0806c3b4cb14c081418abfae8d4442fbc792c2f7958f51e510
 DIST gentoo-kernel-5.4.140-1.x86.xpak 53160196 BLAKE2B 9230edc3d36d4aae621bbdf79262b824a8b9810c7a253b4b09ba7bc0974baedb53f43c70fd6cfaf67b470a50f82fb119a7cf33d425f63e9e50fca4a9570c322f SHA512 29aa547d20e415a50738b3615f25c9f4ebddbcd8d4e9db43aaa8651f40b1e1a93f953ba66963a3c0ba3cdd46d259a638107711e0d3830013359e34346ccf78ea
 DIST gentoo-kernel-5.4.141-1.amd64.xpak 61375880 BLAKE2B 036d0b336dc8c2a25bd405eec7aaf4b64f210521188c36b006dde92b5ccee0440ab55720158d5036e7faa44cd0265ebc1dbcee2309fea783e27fa33952a7031b SHA512 811bbf3f23d66a71bb8df81790b5b0d118d5d323ac5d5bb5a3d67f2d12a12b34766b4503f2d3a08367dac1b4a696dc479139b7e026f4e9beebb2acdb96c20c47
+DIST gentoo-kernel-5.4.141-1.arm64.xpak 58041316 BLAKE2B ca38f602244e24e57ff7172044ac287bb2d629b359a24d622d8c8edef6537d3b7c32bd2a6062fd0271a72db5e00ffd16504093352554beef4187e32371c62b57 SHA512 7ecb91fec0094af236dd598b2fffcaed1cef4efec646fe0e0521fb3818ff908a15c1c265b00d60b110b051573a653fe086918d4fd7f82e0e47900422a1ed80be
 DIST gentoo-kernel-5.4.141-1.x86.xpak 53163945 BLAKE2B 15da6e1ece1dc0484915a10f192a12c1f6176cee4343bf2c6b096db0d740726f71a991c49f1f3cbf26ca50f902539d635e9e0cea7bd55522e132dd582915d804 SHA512 27f6b23993389736de1a864e9ad2d8cdd7d5af9bc12b064918748cf10a48e6cdcc0a157b5c7e833bbcf82a3c98e9b538a643caba4f925e28975fb55c95b5afa3
 DIST gentoo-kernel-5.4.142-1.amd64.xpak 61382010 BLAKE2B 5753309c6f0e98adf348b332ef8acad749f0501b5a0641f2436c7ca7a48c6e57d9f2b316f06d82b5e362cbdf91aa253ba69c7425b6eda0db46531e04929ac6de SHA512 c8433c79fde6bc7b31ff2d93b24e5b327166dcf00157ef91057b006b071f6c7293940285c54f282d40a09957f91831dac9f622dd477be62ec8fea713b0a6b68e
 DIST gentoo-kernel-5.4.142-1.x86.xpak 53152397 BLAKE2B f8fefb4f35896ce47fbadbe5e800814042214b601fd5c7fc14162cc8fe8ab8bcb4633dc80ad861afa7084e71178b2891b2b73c1bd035b689b113eab5e0499a04 SHA512 ea84fde54ea73836bdbabeffea33003795523f4753c58f49b88577db7405cdc7a5539ac20654cd87f9f5c3f41cb402bd692ef250e4674fe463ce796cf91ee9dd
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.141-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.141-r1.ebuild
new file mode 100644
index 000000000000..fe6e6023d323
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.141-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}