sys-process/psmisc: Bump to version 23.1

Package-Manager: Portage-2.3.6, Repoman-2.3.2

1 files changed, 53 insertions, 0 deletions

diff --git a/sys-process/psmisc/psmisc-23.1.ebuild b/sys-process/psmisc/psmisc-23.1.ebuild
new file mode 100644
index 000000000000..e25d09501c93
--- /dev/null
+++ b/sys-process/psmisc/psmisc-23.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="A set of tools that use the proc filesystem"
+HOMEPAGE="http://psmisc.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="ipv6 nls selinux X"
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7:0=
+	nls? ( virtual/libintl )
+	selinux? ( sys-libs/libselinux )"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2.2.6b
+	nls? ( sys-devel/gettext )"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable selinux)
+		--disable-harden-flags
+		$(use_enable ipv6)
+		$(use_enable nls)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	# peekfd is a fragile crap hack #330631
+	nonfatal emake -C src peekfd || touch src/peekfd{.o,}
+	emake
+}
+
+src_install() {
+	default
+
+	use X || rm -f "${ED}"/usr/bin/pstree.x11
+
+	[[ -s ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/bin/peekfd
+	[[ -e ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/share/man/man1/peekfd.1
+
+	# fuser is needed by init.d scripts; use * wildcard for #458250
+	dodir /bin
+	mv "${ED}"/usr/bin/*fuser "${ED}"/bin || die
+}