sys-process/xjobs: new version 20190725.

This version comes with a few fixes/improvements:

  * An update to EAPI=7.

  * A patch to fix the build against separate libtinfo (bug #689982).
    Upstream will include a similar fix in subsequent versions.

  * An unconditional build/runtime dependency on ncurses/libtinfo
    which are detected and used automagically by the build system.

Bug: https://bugs.gentoo.org/689982
Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/sys-process/xjobs/xjobs-20190725.ebuild b/sys-process/xjobs/xjobs-20190725.ebuild
new file mode 100644
index 000000000000..9a5ad730ef3c
--- /dev/null
+++ b/sys-process/xjobs/xjobs-20190725.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Reads commands line by line and executes them in parallel"
+HOMEPAGE="http://www.maier-komor.de/xjobs.html"
+SRC_URI="http://www.maier-komor.de/${PN}/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+BDEPEND="sys-devel/flex"
+
+# The ncurses/terminfo libraries are used to provide color and status
+# support; but, they're detected and enabled automagically by the build
+# system. Thus it would do no good to hide them behind a USE flag that
+# can't be turned off.
+DEPEND="sys-libs/ncurses:0="
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/search-libtinfo-for-tigetstr-and-tparm.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_install() {
+	default
+	use examples && dodoc -r examples
+}