x11-apps/radeon-profile: Bump to version 20190603

Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 59 insertions, 0 deletions

diff --git a/x11-apps/radeon-profile/Manifest b/x11-apps/radeon-profile/Manifest
index 9306bc955e47..1f442d22f35c 100644
--- a/x11-apps/radeon-profile/Manifest
+++ b/x11-apps/radeon-profile/Manifest
@@ -1 +1,2 @@
 DIST radeon-profile-20190311.tar.gz 381505 BLAKE2B e15fbf60f9b790ef81f6b86f74cdada20fe232d2d1965c35248c33bead5f47503780804f0710c8627e4a487e6f95f6688d0dc52b325c278700f9539773547729 SHA512 285ff4fd9f4376135a38009e0e531ec9d9c727840284d9cb4135e0044134a778786559b4280e329be8b78d635928feacd1c0ccc15bce15297d15e4f065460463
+DIST radeon-profile-20190603.tar.gz 382652 BLAKE2B 60d22d59bcc0d91a70775579877300b6e2191187c295da2761b0be3bbac0d761e8a82a9bec958afabec652f6920439c48dedbeeb520849360f890e8205aa39ec SHA512 5def76cd69e347d3caf0ffbd6ae41982e516e72cb869b019f31316bcfaaa4487fd6ec87c7598d56e01640874f3e1d08febdb8e62362851bd6d7c3dc2f2cfb347
diff --git a/x11-apps/radeon-profile/radeon-profile-20190603.ebuild b/x11-apps/radeon-profile/radeon-profile-20190603.ebuild
new file mode 100644
index 000000000000..de8838c90ba8
--- /dev/null
+++ b/x11-apps/radeon-profile/radeon-profile-20190603.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils
+
+DESCRIPTION="Read current clocks of ATi/AMD Radeon cards"
+HOMEPAGE="https://github.com/marazmista/radeon-profile"
+if [[ "${PV}" == 99999999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/marazmista/radeon-profile.git"
+else
+	SRC_URI="https://github.com/marazmista/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE=""
+
+S="${WORKDIR}/${P}/${PN}"
+
+RDEPEND="
+	dev-qt/qtcharts:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	x11-libs/libX11
+	x11-libs/libXrandr
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-qt/qtconcurrent:5
+	media-libs/mesa
+	x11-libs/libdrm
+"
+
+src_prepare() {
+	default
+	sed 's@TrayIcon;@@' -i extra/${PN}.desktop || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}
+
+pkg_postinst() {
+	elog "In order to run ${PN} as non-root user, the"
+	elog "  x11-apps/radeon-profile-daemon"
+	elog "package needs to be installed and the daemon must run."
+}