x11-misc/pcmanfm: version bump to 1.2.4

Also fix duplicate global definition, bump EAPI to 6.

Package-Manager: portage-2.3.0

1 files changed, 72 insertions, 0 deletions

diff --git a/x11-misc/pcmanfm/pcmanfm-1.2.4.ebuild b/x11-misc/pcmanfm/pcmanfm-1.2.4.ebuild
new file mode 100644
index 000000000000..81eafd6feec8
--- /dev/null
+++ b/x11-misc/pcmanfm/pcmanfm-1.2.4.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+PLOCALES="ar be bg bn ca cs da de el en_GB es et eu fa fi fo fr gl he hr hu id
+is it ja kk km ko lg lt lv ms nl pa pl pt pt_BR ro ru si sk sl sr sr@latin sv
+te th tr tt_RU ug uk vi zh_CN zh_TW"
+PLOCALE_BACKUP="en_GB"
+
+inherit eutils fdo-mime l10n readme.gentoo-r1
+
+MY_PV="${PV/_/}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Fast lightweight tabbed filemanager"
+HOMEPAGE="http://pcmanfm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~mips ~ppc ~x86"
+IUSE="debug"
+# Upstream report:
+# https://sourceforge.net/p/pcmanfm/bugs/1026/
+PATCHES=( "${FILESDIR}/${P}-fix-no-common.patch" )
+
+RDEPEND=">=dev-libs/glib-2.18:2
+	>=x11-libs/gtk+-2.16:2
+	>=lxde-base/menu-cache-0.3.2
+	x11-misc/shared-mime-info
+	>=x11-libs/libfm-${PV}:=[gtk(+)]
+	virtual/eject
+	virtual/freedesktop-icon-theme"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+S="${WORKDIR}"/${MY_P}
+
+DOCS=( AUTHORS )
+
+DOC_CONTENTS="PCmanFM can optionally support the menu://applications/
+	location. You should install lxde-base/lxmenu-data for that functionality."
+
+src_prepare() {
+	export LINGUAS="${LINGUAS:-${PLOCALE_BACKUP}}"
+	l10n_get_locales > "${S}"/po/LINGUAS
+	default
+}
+
+src_configure() {
+	econf --sysconfdir=/etc $(use_enable debug)
+}
+
+src_install() {
+	default
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}