proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 60 insertions, 0 deletions

diff --git a/x11-misc/xplanetFX/xplanetFX-2.6.4.ebuild b/x11-misc/xplanetFX/xplanetFX-2.6.4.ebuild
new file mode 100644
index 000000000000..c233273cae8f
--- /dev/null
+++ b/x11-misc/xplanetFX/xplanetFX-2.6.4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils python-r1
+
+DESCRIPTION="User-friendly interface to configure, run or daemonize xplanet with HQ capabilities"
+HOMEPAGE="http://mein-neues-blog.de/xplanetFX/"
+SRC_URI="http://repository.mein-neues-blog.de:9000/archive/${P/FX/fx}_all.tar.gz"
+
+LICENSE="WTFPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libnotify"
+
+DEPEND=""
+RDEPEND="${DEPEND}
+	dev-python/pygtk[${PYTHON_USEDEP}]
+	media-gfx/imagemagick
+	sys-devel/bc
+	x11-misc/xplanet
+	libnotify? ( x11-libs/libnotify )"
+#python
+
+S="${WORKDIR}/usr"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-gentoo-path.patch
+	sed -e "s/Application;//" -i share/applications/*desktop || die
+
+	# These will be installed separately
+	mkdir gentoo || die
+	mv share/${PN}/{autostart,flipview.py,stars/catalog.py,xplanetFX_gtk,xplanetFX_tray} \
+		gentoo || die
+}
+
+src_install() {
+	dobin bin/${PN}
+	insinto /usr/share/applications
+	doins share/applications/${PN}.desktop
+	insinto /usr/share/pixmaps
+	doins share/pixmaps/*
+	insinto /usr/share/${PN}
+	doins -r share/${PN}/*
+
+	exeinto /usr/share/${PN}
+	doexe gentoo/autostart
+
+	dodoc share/doc/${PN}/{changelog,README}
+
+	python_scriptinto /usr/share/${PN}/stars
+	python_foreach_impl python_doscript gentoo/catalog.py
+	python_scriptinto /usr/share/${PN}
+	python_foreach_impl python_doscript gentoo/{xplanetFX_gtk,xplanetFX_tray}
+	python_foreach_impl python_domodule gentoo/flipview.py
+}