x11-plugins/wmmaiload: multiple build fixes

Fix build with -fno-common
Set CPP
Use patch for SSL fix, bump EAPI

Closes: https://bugs.gentoo.org/708542
Closes: https://bugs.gentoo.org/760588
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/x11-plugins/wmmaiload/wmmaiload-2.3.0-r2.ebuild b/x11-plugins/wmmaiload/wmmaiload-2.3.0-r2.ebuild
new file mode 100644
index 000000000000..79edd2c03eb7
--- /dev/null
+++ b/x11-plugins/wmmaiload/wmmaiload-2.3.0-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs
+
+DESCRIPTION="dockapp that monitors one or more mailboxes"
+HOMEPAGE="http://tnemeth.free.fr/projets/dockapps.html"
+SRC_URI="http://tnemeth.free.fr/projets/programmes/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+RDEPEND="x11-libs/gtk+:2
+	x11-libs/libXpm"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.2.1-checkthread.patch
+	"${FILESDIR}"/${P}-fno-common.patch
+	"${FILESDIR}"/${P}-ssl.patch
+)
+
+src_configure() {
+	# The ./configure script is not autoconf based, therefore don't use econf:
+	./configure -p /usr || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CPP="$(tc-getCPP)" \
+		CFLAGS="${CFLAGS}" \
+		DEBUG_LDFLAGS="" \
+		LDFLAGS="${LDFLAGS}" \
+		DEBUG_CFLAGS=""
+}
+
+src_install() {
+	dobin ${PN}/${PN} ${PN}-config/${PN}-config
+	doman doc/*.1
+	dodoc AUTHORS ChangeLog FAQ NEWS README THANKS TODO doc/sample.${PN}rc
+}