x11-wm/enlightenment: bump to 0.23.0

Package-Manager: Portage-2.3.72, Repoman-2.3.17
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/x11-wm/enlightenment/Manifest b/x11-wm/enlightenment/Manifest
index 46b3d3c8e60b..f315e95b03fe 100644
--- a/x11-wm/enlightenment/Manifest
+++ b/x11-wm/enlightenment/Manifest
@@ -1 +1,2 @@
 DIST enlightenment-0.22.4.tar.xz 25656972 BLAKE2B 5e24e226e5f9295d27658656aefaf39cc80ad3634ba1937ef1a3c8e1adeba8cf3cbab2c43cb9e80ac298107a7a64e248ff252084b19c26a974ffff9eb9e6c3fa SHA512 9f4366bfed4d65e7baaeffd4f5b8ba6febf6f9888e6156dd3e100c9fca42c377f76f156f3dd1f6ab97745ffcb69e1e8d320937e41333797580624a9b74d298ba
+DIST enlightenment-0.23.0.tar.xz 26425732 BLAKE2B 2b0bd2f27f5589eb4fa9e1cdd0f2713db26eef36ac204f666dded8a07e91edd260192d413b88e82609c700a71a3459defe8dcae6b778601473c32565799c15c8 SHA512 e49ed9d1d1725cbfd488eb654c3fbe60700382e26136d568b23452cff0112c49953633fd7ac9df7b64f910d37679681b2b9b417d710f46608e97c4060362c7d8
diff --git a/x11-wm/enlightenment/enlightenment-0.23.0.ebuild b/x11-wm/enlightenment/enlightenment-0.23.0.ebuild
new file mode 100644
index 000000000000..7b8666c73e67
--- /dev/null
+++ b/x11-wm/enlightenment/enlightenment-0.23.0.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils meson xdg-utils
+
+DESCRIPTION="Enlightenment window manager"
+HOMEPAGE="https://www.enlightenment.org"
+SRC_URI="https://download.enlightenment.org/rel/apps/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0.17/${PV%%_*}"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
+IUSE="acpi bluetooth connman doc geolocation nls packagekit pam systemd udisks wayland wifi xwayland"
+
+REQUIRED_USE="xwayland? ( wayland )"
+
+RDEPEND="
+	>=dev-libs/efl-1.22.3[eet]
+	virtual/udev
+	x11-libs/libXext
+	x11-libs/libxcb
+	x11-libs/xcb-util-keysyms
+	x11-misc/xkeyboard-config
+	acpi? ( sys-power/acpid )
+	bluetooth? ( net-wireless/bluez )
+	connman? ( dev-libs/efl[connman] )
+	geolocation? ( app-misc/geoclue:2.0 )
+	packagekit? ( app-admin/packagekit-base )
+	pam? ( sys-libs/pam )
+	systemd? ( sys-apps/systemd )
+	udisks? ( sys-fs/udisks:2 )
+	wayland? (
+		>=dev-libs/efl-1.22.0[drm,wayland]
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+		x11-libs/pixman
+	)
+	xwayland? (
+		dev-libs/efl[X,wayland]
+		x11-base/xorg-server[wayland]
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local emesonargs=(
+		-D device-udev=true
+		-D install-enlightenment-menu=true
+
+		-D bluez4=false
+		-D install-sysactions=false
+		-D mount-eeze=false
+
+		$(meson_use udisks mount-udisks)
+		$(meson_use bluetooth bluez5)
+		$(meson_use connman)
+		$(meson_use geolocation)
+		$(meson_use nls)
+		$(meson_use packagekit)
+		$(meson_use pam)
+		$(meson_use systemd)
+		$(meson_use wayland wl)
+		$(meson_use wifi wireless)
+		$(meson_use xwayland)
+	)
+
+	if ! use wayland; then
+		emesonargs+=(
+			-D wl-buffer=false
+			-D wl-desktop-shell=false
+			-D wl-drm=false
+			-D wl-text-input=false
+			-D wl-weekeyboard=false
+			-D wl-wl=false
+			-D wl-x11=false
+		)
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	insinto /etc/enlightenment
+	newins "${FILESDIR}"/gentoo-sysactions.conf sysactions.conf
+
+	use doc && local HTML_DOCS=( doc/. )
+	meson_src_install
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+
+	einfo "Additional programs to complete full EFL suite: "
+	optfeature "an EFL-based IDE" dev-util/edi
+	optfeature "image viewer" media-gfx/ephoto
+	optfeature "ConnMan user interface for Enlightenment" net-misc/econnman
+	optfeature "system and process monitor" sys-process/evisum
+	optfeature "downloading themes and add-ons" x11-misc/enlightenment-extra
+	optfeature "feature rich terminal emulator" x11-terms/terminology
+	optfeature "a matching GTK theme" x11-themes/e-gtk-theme
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}