1 files changed, 53 insertions, 0 deletions
diff --git a/app-admin/supernova/supernova-2.0.7.ebuild b/app-admin/supernova/supernova-2.0.7.ebuild
new file mode 100644
index 000000000000..e4f0808bfc8d
--- /dev/null
+++ b/app-admin/supernova/supernova-2.0.7.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/supernova/supernova-2.0.5.ebuild,v 1.1 2015/08/01 22:14:19 alunduil Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="novaclient wrapper for multiple nova environments"
+HOMEPAGE="https://github.com/rackerhacker/supernova"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc examples test"
+
+CDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="
+	${CDEPEND}
+	doc? ( >=dev-python/mkdocs-0.14.0[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+RDEPEND="
+	${CDEPEND}
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/configobj[${PYTHON_USEDEP}]
+	>=dev-python/keyring-0.9.2[${PYTHON_USEDEP}]
+	dev-python/python-novaclient[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+python_compile_all() {
+	if use doc; then
+		mkdocs build || die "docs failed to build"
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	py.test || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( site/. )
+	use examples && local EXAMPLES=( example_configs/. )
+
+	distutils-r1_python_install_all
+
+	newbashcomp contrib/${PN}-completion.bash ${PN}
+}