1 files changed, 66 insertions, 0 deletions
diff --git a/app-backup/qt4-fsarchiver/qt4-fsarchiver-0.6.19.7.ebuild b/app-backup/qt4-fsarchiver/qt4-fsarchiver-0.6.19.7.ebuild
new file mode 100644
index 000000000000..1bcf6b5b11fc
--- /dev/null
+++ b/app-backup/qt4-fsarchiver/qt4-fsarchiver-0.6.19.7.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit qmake-utils versionator
+
+MY_P="${PN}-$(replace_version_separator 3 '-')"
+MIN_PV="$(get_version_component_range 1-3)"
+
+DESCRIPTION="Qt4 frontend for fsarchiver"
+HOMEPAGE="http://qt4-fsarchiver.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/source/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE=""
+
+CDEPEND="app-arch/bzip2
+	app-arch/xz-utils
+	dev-libs/libgcrypt:=
+	dev-libs/lzo
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	sys-apps/util-linux
+	sys-fs/e2fsprogs
+	sys-libs/zlib"
+RDEPEND="${CDEPEND}
+	>=app-backup/fsarchiver-${MIN_PV}[lzma,lzo]"
+DEPEND="${CDEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	# fix .desktop file
+	sed -i \
+		-e '/Encoding/d' starter/"${PN}".desktop \
+		|| die "sed on qt4-fsarchiver.desktop failed"
+	# fix icon installation location
+	sed -i \
+		-e "/icon.path/s:app-install/icons:${PN}:" "${PN}.pro" \
+		|| die "sed on ${PN}.pro failed"
+}
+
+src_compile() {
+	eqmake4
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}
+
+pkg_postinst() {
+	elog "optional dependencies:"
+	elog "  sys-fs/btrfs-progs"
+	elog "  sys-fs/jfsutils"
+	elog "  sys-fs/ntfs3g[ntfsprogs]"
+	elog "  sys-fs/reiser4progs"
+	elog "  sys-fs/reiserfsprogs"
+	elog "  sys-fs/sshfs-fuse"
+	elog "  sys-fs/xfsprogs"
+}