Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status
summaryrefslogtreecommitdiff
path: root/app-editors/bluefish
diff options
context:
space:
mode:
Diffstat (limited to 'app-editors/bluefish')
-rw-r--r--app-editors/bluefish/Manifest2
-rw-r--r--app-editors/bluefish/bluefish-2.2.12-r2.ebuild98
-rw-r--r--app-editors/bluefish/bluefish-2.2.13.ebuild (renamed from app-editors/bluefish/bluefish-2.2.12.ebuild)43
-rw-r--r--app-editors/bluefish/bluefish-2.2.15.ebuild97
-rw-r--r--app-editors/bluefish/files/bluefish-2.2.9-fix-incompatible-pointer.patch20
-rw-r--r--app-editors/bluefish/metadata.xml2
6 files changed, 242 insertions, 20 deletions
diff --git a/app-editors/bluefish/Manifest b/app-editors/bluefish/Manifest
index 91678c89959b..1aea6e3f7ac5 100644
--- a/app-editors/bluefish/Manifest
+++ b/app-editors/bluefish/Manifest
@@ -1 +1,3 @@
DIST bluefish-2.2.12.tar.bz2 4180228 BLAKE2B 9e05a4618c37951da6a669e9bd4e0dd7e9993ea764dd467f875039b28cdc6d71ae70d1a87df7f0c63f850ebbff6ceeb8550d1d036bab32b7435f362d5b137147 SHA512 f0eb6496d371db8a9b4aee33ddf67e5e87bcc86ff283704cac115be7f00609b1ccbd47ff2d8f8b0bc30f234a339069cc1f7cb1f8809d97f94f0b0e09e4f16754
+DIST bluefish-2.2.13.tar.bz2 4254294 BLAKE2B 7d830fa19cfeaac56c7823760e789b32306d74156a8c106a2ba847c2ecc535a47eae59a76594afea1c013bd2f8d40107cd02f46b0871e69d6db9307fae77a606 SHA512 959a260f32c7e90ad5b3acc52eaa4a1cc979c7a41d2fa8e3b1f9bd139232c1af940bdc92c84d00b30c53389e25b2b92188cde569bc39bdda5208e1ebec20eb68
+DIST bluefish-2.2.15.tar.bz2 4762151 BLAKE2B 18ea676f0853435203f119788082057dde499ce65a9ba3ac5e3a79c6cde26b6dd88694542d966f5c88d10b4aeaf8ae9ce016427491bed4a188037cf8685b59bf SHA512 86c31eba1bbc954d1dd39c5db8b9a276e6893e97130b259ee7eb3c32dd98510ce9d95b2d8f0922ac361fa7bc645e4e6251a97fc7da61cdcfaaf29f84b7ea38c7
diff --git a/app-editors/bluefish/bluefish-2.2.12-r2.ebuild b/app-editors/bluefish/bluefish-2.2.12-r2.ebuild
new file mode 100644
index 000000000000..97d13fcb5744
--- /dev/null
+++ b/app-editors/bluefish/bluefish-2.2.12-r2.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+MY_P=${P/_/-}
+inherit autotools python-single-r1 xdg
+
+DESCRIPTION="GTK HTML editor for the experienced web designer or programmer"
+HOMEPAGE="https://bluefish.openoffice.nl/"
+SRC_URI="https://www.bennewitz.com/bluefish/stable/source/${MY_P}.tar.bz2"
+
+LICENSE="GPL-3+"
+KEYWORDS="~alpha amd64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc x86"
+SLOT="0"
+IUSE="gucharmap nls python spell"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="sys-libs/zlib
+ x11-libs/gtk+:3
+ gucharmap? ( gnome-extra/gucharmap:2.90 )
+ python? ( ${PYTHON_DEPS} )
+ spell? ( app-text/enchant:2 )"
+DEPEND="${RDEPEND}
+ x11-libs/pango"
+BDEPEND=">=dev-libs/glib-2.24:2
+ dev-libs/libxml2:2
+ virtual/pkgconfig
+ nls? (
+ dev-util/intltool
+ sys-devel/gettext
+ )"
+
+S="${WORKDIR}/${MY_P}"
+
+# there actually is just some broken manpage checkup -> not bother
+RESTRICT="test"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-2.2.9-charmap_configure.patch"
+ "${FILESDIR}/${PN}-2.2.9-fix-incompatible-pointer.patch"
+)
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+
+ # eautoreconf seems to no longer kill translation files.
+ eautoreconf
+ sed -i 's:gzip -n $< -c:gzip -n -c $<:' data/bflib/Makefile.* || die "Cannot fix makefile"
+}
+
+src_configure() {
+ CONFIG_SHELL="${BROOT}/bin/bash" econf \
+ --disable-update-databases \
+ --disable-xml-catalog-update \
+ --with-freedesktop_org-appdata="${EPREFIX}"/usr/share/metainfo \
+ --without-gtk2 \
+ $(use_with gucharmap charmap) \
+ $(use_enable nls) \
+ $(use_enable spell spell-check) \
+ $(use_enable python)
+}
+
+src_install() {
+ default
+
+ find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ einfo "Adding XML catalog entries..."
+ "${EPREFIX}"/usr/bin/xmlcatalog --noout \
+ --add 'public' 'Bluefish/DTD/Bflang' 'bflang.dtd' \
+ --add 'system' 'http://bluefish.openoffice.nl/DTD/bflang.dtd' 'bflang.dtd' \
+ --add 'rewriteURI' 'http://bluefish.openoffice.nl/DTD' '/usr/share/xml/bluefish-unstable' \
+ "${EROOT}"/etc/xml/catalog \
+ || ewarn "Failed to add XML catalog entries."
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+
+ einfo "Removing XML catalog entries..."
+ "${EPREFIX}"/usr/bin/xmlcatalog --noout \
+ --del 'Bluefish/DTD/Bflang' \
+ --del 'http://bluefish.openoffice.nl/DTD/bflang.dtd' \
+ --del 'http://bluefish.openoffice.nl/DTD' \
+ "${EROOT}"/etc/xml/catalog \
+ || ewarn "Failed to remove XML catalog entries."
+}
diff --git a/app-editors/bluefish/bluefish-2.2.12.ebuild b/app-editors/bluefish/bluefish-2.2.13.ebuild
index 625cc993be5c..4893fb9098ca 100644
--- a/app-editors/bluefish/bluefish-2.2.12.ebuild
+++ b/app-editors/bluefish/bluefish-2.2.13.ebuild
@@ -1,37 +1,36 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
-EAPI=7
+EAPI=8
-PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_COMPAT=( python3_{9..11} )
MY_P=${P/_/-}
inherit autotools python-single-r1 xdg
-DESCRIPTION="A GTK HTML editor for the experienced web designer or programmer"
-HOMEPAGE="http://bluefish.openoffice.nl/"
+DESCRIPTION="GTK HTML editor for the experienced web designer or programmer"
+HOMEPAGE="https://bluefish.openoffice.nl/"
SRC_URI="https://www.bennewitz.com/bluefish/stable/source/${MY_P}.tar.bz2"
-LICENSE="GPL-2"
-KEYWORDS="~alpha amd64 ~ia64 ~ppc ~ppc64 ~sparc x86"
+LICENSE="GPL-3+"
+KEYWORDS="~alpha amd64 ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc x86"
SLOT="0"
IUSE="gucharmap nls python spell"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-RDEPEND="
- sys-libs/zlib
+RDEPEND="sys-libs/zlib
x11-libs/gtk+:3
gucharmap? ( gnome-extra/gucharmap:2.90 )
python? ( ${PYTHON_DEPS} )
- spell? ( >=app-text/enchant-1.4:0 )"
+ spell? ( app-text/enchant:2 )"
DEPEND="${RDEPEND}
x11-libs/pango"
BDEPEND=">=dev-libs/glib-2.24:2
dev-libs/libxml2:2
virtual/pkgconfig
nls? (
- sys-devel/gettext
dev-util/intltool
+ sys-devel/gettext
)"
S="${WORKDIR}/${MY_P}"
@@ -39,21 +38,24 @@ S="${WORKDIR}/${MY_P}"
# there actually is just some broken manpage checkup -> not bother
RESTRICT="test"
+PATCHES=(
+ "${FILESDIR}/${PN}-2.2.9-charmap_configure.patch"
+)
+
pkg_setup() {
use python && python-single-r1_pkg_setup
}
-PATCHES=( "${FILESDIR}/${PN}-2.2.9-charmap_configure.patch" )
-
-# eautoreconf seems to no longer kill translation files.
src_prepare() {
default
+
+ # eautoreconf seems to no longer kill translation files.
eautoreconf
sed -i 's:gzip -n $< -c:gzip -n -c $<:' data/bflib/Makefile.* || die "Cannot fix makefile"
}
src_configure() {
- econf \
+ CONFIG_SHELL="${BROOT}/bin/bash" econf \
--disable-update-databases \
--disable-xml-catalog-update \
--with-freedesktop_org-appdata="${EPREFIX}"/usr/share/metainfo \
@@ -66,27 +68,30 @@ src_configure() {
src_install() {
default
+
find "${ED}" -name '*.la' -delete || die
}
pkg_postinst() {
xdg_pkg_postinst
+
einfo "Adding XML catalog entries..."
- /usr/bin/xmlcatalog --noout \
+ "${EPREFIX}"/usr/bin/xmlcatalog --noout \
--add 'public' 'Bluefish/DTD/Bflang' 'bflang.dtd' \
--add 'system' 'http://bluefish.openoffice.nl/DTD/bflang.dtd' 'bflang.dtd' \
--add 'rewriteURI' 'http://bluefish.openoffice.nl/DTD' '/usr/share/xml/bluefish-unstable' \
- /etc/xml/catalog \
+ "${EROOT}"/etc/xml/catalog \
|| ewarn "Failed to add XML catalog entries."
}
pkg_postrm() {
xdg_pkg_postrm
+
einfo "Removing XML catalog entries..."
- /usr/bin/xmlcatalog --noout \
+ "${EPREFIX}"/usr/bin/xmlcatalog --noout \
--del 'Bluefish/DTD/Bflang' \
--del 'http://bluefish.openoffice.nl/DTD/bflang.dtd' \
--del 'http://bluefish.openoffice.nl/DTD' \
- /etc/xml/catalog \
+ "${EROOT}"/etc/xml/catalog \
|| ewarn "Failed to remove XML catalog entries."
}
diff --git a/app-editors/bluefish/bluefish-2.2.15.ebuild b/app-editors/bluefish/bluefish-2.2.15.ebuild
new file mode 100644
index 000000000000..d5021225b6ab
--- /dev/null
+++ b/app-editors/bluefish/bluefish-2.2.15.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+
+MY_P=${P/_/-}
+inherit autotools python-single-r1 xdg
+
+DESCRIPTION="GTK HTML editor for the experienced web designer or programmer"
+HOMEPAGE="https://bluefish.openoffice.nl/"
+SRC_URI="https://www.bennewitz.com/bluefish/stable/source/${MY_P}.tar.bz2"
+
+S="${WORKDIR}/${MY_P}"
+LICENSE="GPL-3+"
+SLOT="0"
+
+KEYWORDS="~alpha ~amd64 ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="gucharmap nls python spell"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="sys-libs/zlib
+ x11-libs/gtk+:3
+ gucharmap? ( gnome-extra/gucharmap:2.90 )
+ python? ( ${PYTHON_DEPS} )
+ spell? ( app-text/enchant:2 )"
+DEPEND="${RDEPEND}
+ x11-libs/pango"
+BDEPEND=">=dev-libs/glib-2.24:2
+ dev-libs/libxml2:2
+ virtual/pkgconfig
+ nls? (
+ dev-util/intltool
+ sys-devel/gettext
+ )"
+
+# there actually is just some broken manpage checkup -> not bother
+RESTRICT="test"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-2.2.9-charmap_configure.patch"
+)
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+
+ # eautoreconf seems to no longer kill translation files.
+ eautoreconf
+ sed -i 's:gzip -n $< -c:gzip -n -c $<:' data/bflib/Makefile.* || die "Cannot fix makefile"
+}
+
+src_configure() {
+ CONFIG_SHELL="${BROOT}/bin/bash" econf \
+ --disable-update-databases \
+ --disable-xml-catalog-update \
+ --with-freedesktop_org-appdata="${EPREFIX}"/usr/share/metainfo \
+ --without-gtk2 \
+ $(use_with gucharmap charmap) \
+ $(use_enable nls) \
+ $(use_enable spell spell-check) \
+ $(use_enable python)
+}
+
+src_install() {
+ default
+
+ find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ einfo "Adding XML catalog entries..."
+ "${EPREFIX}"/usr/bin/xmlcatalog --noout \
+ --add 'public' 'Bluefish/DTD/Bflang' 'bflang.dtd' \
+ --add 'system' 'http://bluefish.openoffice.nl/DTD/bflang.dtd' 'bflang.dtd' \
+ --add 'rewriteURI' 'http://bluefish.openoffice.nl/DTD' '/usr/share/xml/bluefish-unstable' \
+ "${EROOT}"/etc/xml/catalog \
+ || ewarn "Failed to add XML catalog entries."
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+
+ einfo "Removing XML catalog entries..."
+ "${EPREFIX}"/usr/bin/xmlcatalog --noout \
+ --del 'Bluefish/DTD/Bflang' \
+ --del 'http://bluefish.openoffice.nl/DTD/bflang.dtd' \
+ --del 'http://bluefish.openoffice.nl/DTD' \
+ "${EROOT}"/etc/xml/catalog \
+ || ewarn "Failed to remove XML catalog entries."
+}
diff --git a/app-editors/bluefish/files/bluefish-2.2.9-fix-incompatible-pointer.patch b/app-editors/bluefish/files/bluefish-2.2.9-fix-incompatible-pointer.patch
new file mode 100644
index 000000000000..7cf8900d4f9f
--- /dev/null
+++ b/app-editors/bluefish/files/bluefish-2.2.9-fix-incompatible-pointer.patch
@@ -0,0 +1,20 @@
+Clang16 will not allow to assign incompatible pointer types by default.
+Therefore we need to and const to the third parameter of this function
+to match the pointer XmlHashScanner this function is later assigned to.
+
+Bug: https://bugs.gentoo.org/882207
+Patch has been sent to upstream here: https://sourceforge.net/p/bluefish/tickets/66/
+
+Pascal Jäger <pascal.jaeger@leimstift.de> (2022-12-07)
+
+--- a/src/plugin_infbrowser/infb_dtd.c
++++ b/src/plugin_infbrowser/infb_dtd.c
+@@ -80,7 +80,7 @@ static gchar *infb_dtd_str_content(xmlElementContentPtr ct,gchar *sofar) {
+ return ret;
+ }
+
+-static void infb_dtd_element_to_group(void *payload, void *data, xmlChar *name) {
++static void infb_dtd_element_to_group(void *payload, void *data,const xmlChar *name) {
+ xmlElementPtr el = (xmlElementPtr)payload;
+ switch(name[0]) {
+ case 'a':case 'b':case 'c':case 'd':case 'e':
diff --git a/app-editors/bluefish/metadata.xml b/app-editors/bluefish/metadata.xml
index 56419257845e..1b7846505de4 100644
--- a/app-editors/bluefish/metadata.xml
+++ b/app-editors/bluefish/metadata.xml
@@ -1,5 +1,5 @@
<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<!-- maintainer-needed -->
<use>