1 files changed, 46 insertions, 0 deletions
diff --git a/app-forensics/radamsa/radamsa-0.7.ebuild b/app-forensics/radamsa/radamsa-0.7.ebuild
new file mode 100644
index 000000000000..baf922c968eb
--- /dev/null
+++ b/app-forensics/radamsa/radamsa-0.7.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+MY_P="${PN}-v${PV}"
+
+DESCRIPTION="A general-purpose fuzzer"
+HOMEPAGE="https://gitlab.com/akihe/radamsa"
+SRC_URI="
+	https://gitlab.com/akihe/${PN}/-/archive/v${PV}/${MY_P}.tar.bz2
+	https://gitlab.com/akihe/${PN}/uploads/d774a42f7893012d0a56c490a75ae12b/${P}.c.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# needs an owl-lisp
+RESTRICT=test
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.7_prebuilt-c.patch
+)
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	default
+
+	cp "${WORKDIR}"/${P}.c "${S}"/${PN}.c || die
+}
+
+src_compile() {
+	emake bin/radamsa CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	dobin bin/radamsa
+	# avoid man compression by build system
+	doman doc/radamsa.1
+
+	einstalldocs
+}