1 files changed, 53 insertions, 0 deletions
diff --git a/app-i18n/tagainijisho/tagainijisho-1.0.3-r1.ebuild b/app-i18n/tagainijisho/tagainijisho-1.0.3-r1.ebuild
new file mode 100644
index 000000000000..5fd5b06191ad
--- /dev/null
+++ b/app-i18n/tagainijisho/tagainijisho-1.0.3-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils gnome2-utils
+
+DESCRIPTION="Open-source Japanese dictionary and kanji lookup tool"
+HOMEPAGE="http://www.tagaini.net/"
+SRC_URI="https://github.com/Gnurou/tagainijisho/releases/download/${PV}/${P}.tar.gz"
+LICENSE="GPL-3+ public-domain"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+DEPEND="dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	>=dev-db/sqlite-3.11:3"
+RDEPEND="${DEPEND}"
+
+pkg_linguas=( ar cs de es fa_IR fi_FI fr hu id it nb nl pl pt ru sv th tr vi )
+IUSE+=" ${pkg_linguas[@]/#/linguas_}"
+
+PATCHES=( "${FILESDIR}"/${P}-*.patch )
+
+src_configure() {
+	# GUI linguae
+	# en is not optional, and build fails if none other then en is set, so adding ja as non-optional too
+	# linguae undeclared in IUSE will trigger an error, which is a handy check
+	for lingua in $(ls -1 i18n/*.ts | sed -e 's/.*tagainijisho_\(.*\)\.ts/\1/' | grep -v en | grep -v ja); do
+		if ! use linguas_${lingua}; then
+			rm i18n/tagainijisho_${lingua}.ts || die
+		fi
+	done
+
+	# Dictionary linguae
+	# en is not optional here either, but nothing special needs to be done
+	# here too, linguae undeclared in IUSE will trigger an error
+	local cmake_linguas
+	for lingua in $(sed -e 's/;/ /g' -ne '/set(DICT_LANG ".*")/s/.*"\(.*\)".*/\1/p' CMakeLists.txt); do
+		if use linguas_${lingua}; then
+			cmake_linguas+=";${lingua}"
+		fi
+	done
+	mycmakeargs=( -DDICT_LANG="${cmake_linguas};" )
+
+	cmake-utils_src_configure
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }