1 files changed, 93 insertions, 0 deletions
diff --git a/dev-ada/gprbuild/gprbuild-2018-r3.ebuild b/dev-ada/gprbuild/gprbuild-2018-r3.ebuild
new file mode 100644
index 000000000000..91e3da95792d
--- /dev/null
+++ b/dev-ada/gprbuild/gprbuild-2018-r3.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs multiprocessing
+
+MYP=${PN}-gpl-${PV}
+
+DESCRIPTION="Multi-Language Management"
+HOMEPAGE="http://libre.adacore.com/"
+SRC_URI="
+	http://mirrors.cdn.adacore.com/art/5b0819dfc7a447df26c27a68
+		-> ${MYP}-src.tar.gz
+	http://mirrors.cdn.adacore.com/art/5b0819dec7a447df26c27a40
+		-> xmlada-gpl-${PV}-src.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnat_2016 gnat_2017 +gnat_2018"
+
+DEPEND="gnat_2016? ( dev-lang/gnat-gpl:4.9.4 )
+	gnat_2017? ( dev-lang/gnat-gpl:6.3.0 )
+	gnat_2018? ( dev-lang/gnat-gpl:7.3.1 )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"/${MYP}-src
+
+REQUIRED_USE="!gnat_2016 ^^ ( gnat_2017 gnat_2018 )"
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
+
+src_prepare() {
+	if use gnat_2016; then
+		GCC_PV=4.9.4
+	elif use gnat_2017; then
+		GCC_PV=6.3.0
+	else
+		GCC_PV=7.3.1
+	fi
+	default
+	sed -i \
+		-e "s:@VER@:${GCC_PV}:g" \
+		share/gprconfig/compilers.xml \
+		share/gprconfig/gnat.xml \
+		share/gprconfig/c.xml \
+		share/gprconfig/linker.xml \
+		|| die
+	sed -i \
+		-e "s:@GNATBIND@:gnatbind-${GCC_PV}:g" \
+		src/gprlib.adb \
+		|| die
+#	sed -i \
+#		-e "s:\"-Wl,-r\":\"-r\":g" \
+#		share/gprconfig/linker.xml \
+#		|| die
+}
+
+src_configure() {
+	emake prefix="${D}"usr setup
+}
+
+bin_progs="gprbuild gprconfig gprclean gprinstall gprname gprls"
+lib_progs="gprlib gprbind"
+
+src_compile() {
+	GCC=${CHOST}-gcc-${GCC_PV}
+	GNATMAKE=${CHOST}-gnatmake-${GCC_PV}
+	local xmlada_src="../xmlada-gpl-${PV}-src"
+	incflags="-Isrc -Igpr/src -I${xmlada_src}/sax -I${xmlada_src}/dom \
+		-I${xmlada_src}/schema -I${xmlada_src}/unicode \
+		-I${xmlada_src}/input_sources"
+	${GCC} -c ${CFLAGS} gpr/src/gpr_imports.c -o gpr_imports.o || die
+	for bin in ${bin_progs}; do
+		${GNATMAKE} -j$(makeopts_jobs) ${incflags} $ADAFLAGS ${bin}-main \
+			-o ${bin} -largs gpr_imports.o || die
+	done
+	for lib in $lib_progs; do
+		${GNATMAKE} -j$(makeopts_jobs) ${incflags} ${lib} $ADAFLAGS \
+			-largs gpr_imports.o || die
+	done
+}
+
+src_install() {
+	dobin ${bin_progs}
+	exeinto /usr/libexec/gprbuild
+	doexe ${lib_progs}
+	insinto /usr/share/gprconfig
+	doins share/gprconfig/*
+	insinto /usr/share/gpr
+	doins share/_default.gpr
+	insinto /usr/share/gprconfig
+	einstalldocs
+}