1 files changed, 64 insertions, 0 deletions
diff --git a/dev-libs/mpfr/mpfr-3.0.1_p4-r1.ebuild b/dev-libs/mpfr/mpfr-3.0.1_p4-r1.ebuild
new file mode 100644
index 000000000000..9f726f07915b
--- /dev/null
+++ b/dev-libs/mpfr/mpfr-3.0.1_p4-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="3"
+
+# NOTE: we cannot depend on autotools here starting with gcc-4.3.x
+inherit eutils multilib
+
+MY_PV=${PV/_p*}
+MY_P=${PN}-${MY_PV}
+PLEVEL=${PV/*p}
+DESCRIPTION="library for multiple-precision floating-point computations with exact rounding"
+HOMEPAGE="http://www.mpfr.org/"
+SRC_URI="http://www.mpfr.org/mpfr-${MY_PV}/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="static-libs"
+
+RDEPEND=">=dev-libs/gmp-4.1.4-r2[static-libs?]"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	[[ ${PLEVEL} == ${PV} ]] && return 0
+	for ((i=1; i<=PLEVEL; ++i)) ; do
+		patch=patch$(printf '%02d' ${i})
+		if [[ -f ${FILESDIR}/${MY_PV}/${patch} ]] ; then
+			epatch "${FILESDIR}"/${MY_PV}/${patch}
+		elif [[ -f ${DISTDIR}/${PN}-${MY_PV}_p${i} ]] ; then
+			epatch "${DISTDIR}"/${PN}-${MY_PV}_p${i}
+		else
+			ewarn "${DISTDIR}/${PN}-${MY_PV}_p${i}"
+			die "patch ${i} missing - please report to bugs.gentoo.org"
+		fi
+	done
+	sed -i '/if test/s:==:=:' configure #261016
+	find . -type f -print0 | xargs -0 touch -r configure
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	use static-libs || rm -f "${D}"/usr/$(get_libdir)/libmpfr.la
+	rm "${D}"/usr/share/doc/${PN}/*.html || die
+	mv "${D}"/usr/share/doc/{${PN},${PF}} || die
+	dodoc AUTHORS BUGS ChangeLog NEWS README TODO
+	dohtml *.html
+	prepalldocs
+}
+
+pkg_preinst() {
+	preserve_old_lib /usr/$(get_libdir)/libmpfr.so.1
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/libmpfr.so.1
+}