1 files changed, 36 insertions, 0 deletions
diff --git a/dev-python/exceptiongroup/exceptiongroup-1.2.1.ebuild b/dev-python/exceptiongroup/exceptiongroup-1.2.1.ebuild
new file mode 100644
index 000000000000..112639c10e38
--- /dev/null
+++ b/dev-python/exceptiongroup/exceptiongroup-1.2.1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit_scm
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Backport of PEP 654 (exception groups)"
+HOMEPAGE="
+	https://github.com/agronholm/exceptiongroup/
+	https://pypi.org/project/exceptiongroup/
+"
+
+LICENSE="MIT PSF-2.4"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# https://github.com/agronholm/exceptiongroup/issues/122
+				tests/test_formatting.py
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}