1 files changed, 66 insertions, 0 deletions
diff --git a/dev-python/h5py/h5py-2.5.0.ebuild b/dev-python/h5py/h5py-2.5.0.ebuild
new file mode 100644
index 000000000000..a6218f297931
--- /dev/null
+++ b/dev-python/h5py/h5py-2.5.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Simple Python interface to HDF5 files"
+HOMEPAGE="http://www.h5py.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test examples mpi"
+
+RDEPEND="
+	sci-libs/hdf5:=[mpi=]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/alabaster[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.3.1[${PYTHON_USEDEP}]
+		)
+	mpi? ( dev-python/mpi4py[${PYTHON_USEDEP}] )"
+
+pkg_setup() {
+	use mpi && export CC=mpicc
+}
+
+python_prepare_all() {
+	append-cflags -fno-strict-aliasing
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
+	esetup.py configure $(usex mpi --mpi '')
+}
+
+python_compile_all() {
+	if use doc; then
+		cd "${S}"/docs || die
+		sed '/html_theme/s:default:alabaster:g' -i conf.py || die
+		rm -r _build || die
+		emake html
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	DOCS=( README.rst ANN.rst )
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}