1 files changed, 0 insertions, 54 deletions
diff --git a/dev-python/importlib_metadata/importlib_metadata-4.11.4.ebuild b/dev-python/importlib_metadata/importlib_metadata-4.11.4.ebuild
deleted file mode 100644
index 7cd095140458..000000000000
--- a/dev-python/importlib_metadata/importlib_metadata-4.11.4.ebuild
+++ /dev/null
@@ -1,54 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
-EAPI=7
-
-DISTUTILS_USE_PEP517=flit
-# NB: this package extends beyond built-in importlib stuff in py3.8+
-# new entry_point API not yet included in cpython release
-PYTHON_COMPAT=( pypy3 python3_{8..10} )
-
-inherit distutils-r1
-
-DESCRIPTION="Read metadata from Python packages"
-HOMEPAGE="https://github.com/python/importlib_metadata"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-
-RDEPEND="
-	dev-python/zipp[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/packaging[${PYTHON_USEDEP}]
-		dev-python/pyfakefs[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/importlib_resources[${PYTHON_USEDEP}]
-		' 3.8)
-	)
-"
-
-distutils_enable_sphinx docs \
-	dev-python/jaraco-packaging \
-	dev-python/rst-linker
-distutils_enable_tests unittest
-
-src_configure() {
-	grep -q 'build-backend = "setuptools' pyproject.toml ||
-		die "Upstream changed build-backend, recheck"
-	# write a custom pyproject.toml to ease setuptools bootstrap
-	cat > pyproject.toml <<-EOF || die
-		[build-system]
-		requires = ["flit_core >=3.2,<4"]
-		build-backend = "flit_core.buildapi"
-
-		[project]
-		name = "importlib_metadata"
-		version = "${PV}"
-		description = "Read metadata from Python packages"
-	EOF
-}