1 files changed, 39 insertions, 0 deletions
diff --git a/dev-python/libpillowfight/libpillowfight-0.3.0_p20210816-r1.ebuild b/dev-python/libpillowfight/libpillowfight-0.3.0_p20210816-r1.ebuild
new file mode 100644
index 000000000000..40fbe6ee7378
--- /dev/null
+++ b/dev-python/libpillowfight/libpillowfight-0.3.0_p20210816-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+COMMIT="50d965879eb89fdef9be09d6e934329486ff585d"
+
+DESCRIPTION="Small library containing various image processing algorithms"
+HOMEPAGE="https://gitlab.gnome.org/World/OpenPaperwork/libpillowfight"
+SRC_URI="https://gitlab.gnome.org/World/OpenPaperwork/${PN}/-/archive/${COMMIT}/${P}.tar.bz2"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/pillow[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -e "/'nose>=1.0'/d" -i setup.py || die
+	cat > src/pillowfight/_version.h <<- EOF || die
+		#define INTERNAL_PILLOWFIGHT_VERSION "$(ver_cut 1-3)"
+	EOF
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests -o addopts=
+}