1 files changed, 35 insertions, 0 deletions
diff --git a/dev-python/memory-allocator/memory-allocator-0.1.4.ebuild b/dev-python/memory-allocator/memory-allocator-0.1.4.ebuild
new file mode 100644
index 000000000000..35542831649a
--- /dev/null
+++ b/dev-python/memory-allocator/memory-allocator-0.1.4.ebuild
@@ -0,0 +1,35 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="An extension class for memory allocation in cython"
+HOMEPAGE="
+	https://pypi.org/project/memory-allocator/
+	https://github.com/sagemath/memory_allocator/
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+python_test() {
+	# The test script tries to "import memory_allocator.test" which, so
+	# long as a memory_allocator directory exists inside CWD, will look
+	# for a memory_allocator/test.py there. But there is no such file;
+	# the "test" module is a compiled extension. To let the search fall
+	# back to the correct location, we temporarily rename the directory
+	# that misleads it.
+	rm -rf memory_allocator || die
+	"${EPYTHON}" test.py || die
+}