1 files changed, 55 insertions, 0 deletions
diff --git a/dev-python/numexpr/numexpr-2.5.ebuild b/dev-python/numexpr/numexpr-2.5.ebuild
new file mode 100644
index 000000000000..263d9a72e151
--- /dev/null
+++ b/dev-python/numexpr/numexpr-2.5.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Fast numerical array expression evaluator for Python and NumPy"
+HOMEPAGE="https://github.com/pydata/numexpr"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="mkl"
+
+RDEPEND="
+	>=dev-python/numpy-1.6[${PYTHON_USEDEP}]
+	mkl? ( sci-libs/mkl )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# TODO: mkl can be used but it fails for me
+	# only works with mkl in tree. newer mkl will use pkgconfig
+	if use mkl; then
+		local ext
+		use amd64 && ext=_lp64
+		cat <<- EOF > "${S}"/site.cfg
+		[mkl]
+		library_dirs = ${MKLROOT}/lib/em64t
+		include_dirs = ${MKLROOT}/include
+		mkl_libs = mkl_solver${ext}, mkl_intel${ext}, \
+		mkl_intel_thread, mkl_core, iomp5
+		EOF
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	pushd "${BUILD_DIR}"/lib > /dev/null
+	"${PYTHON}" \
+		-c "import sys;import numexpr;sys.exit(0 if numexpr.test() else 1)" \
+		|| die
+	pushd > /dev/null
+}