1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/pytest-xdist/pytest-xdist-1.34.0.ebuild b/dev-python/pytest-xdist/pytest-xdist-1.34.0.ebuild
new file mode 100644
index 000000000000..963bc520b04c
--- /dev/null
+++ b/dev-python/pytest-xdist/pytest-xdist-1.34.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python2_7 python3_{6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Distributed testing and loop-on-failing modes"
+HOMEPAGE="https://pypi.org/project/pytest-xdist/ https://github.com/pytest-dev/pytest-xdist"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# pleaes do not depend on pytest to avoid unnecessary USEDEP enforcement
+RDEPEND="
+	dev-python/execnet[${PYTHON_USEDEP}]
+	dev-python/pytest-forked[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/filelock[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/pytest-xdist-1.32.0-timeout.patch
+)
+
+python_test() {
+	distutils_install_for_testing
+	pytest -vv testing || die "Tests failed under ${EPYTHON}"
+}