1 files changed, 45 insertions, 0 deletions
diff --git a/dev-python/sphinxcontrib-trio/sphinxcontrib-trio-1.1.2-r1.ebuild b/dev-python/sphinxcontrib-trio/sphinxcontrib-trio-1.1.2-r1.ebuild
new file mode 100644
index 000000000000..66e52305a688
--- /dev/null
+++ b/dev-python/sphinxcontrib-trio/sphinxcontrib-trio-1.1.2-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Make Sphinx better at documenting Python functions and methods"
+HOMEPAGE="
+	https://github.com/python-trio/sphinxcontrib-trio
+	https://pypi.org/project/sphinxcontrib-trio/
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
+SLOT="0"
+
+RDEPEND="
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cssselect[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+"
+
+# AttributeError: 'Sphinx' object has no attribute 'add_stylesheet'
+#distutils_enable_sphinx docs/source
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# https://github.com/python-trio/sphinxcontrib-trio/issues/260
+		tests/test_sphinxcontrib_trio.py::test_end_to_end
+	)
+
+	local -x PYTHONPATH="${BUILD_DIR}/install$(python_get_sitedir)"
+	epytest
+}