1 files changed, 49 insertions, 0 deletions
diff --git a/dev-util/cunit/cunit-2.1_p2.ebuild b/dev-util/cunit/cunit-2.1_p2.ebuild
new file mode 100644
index 000000000000..854eccb3f7a8
--- /dev/null
+++ b/dev-util/cunit/cunit-2.1_p2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils flag-o-matic toolchain-funcs
+
+MY_PN='CUnit'
+MY_PV="${PV/_p*}-2"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="CUnit - C Unit Test Framework"
+SRC_URI="mirror://sourceforge/cunit/${MY_P}-src.tar.bz2"
+HOMEPAGE="http://cunit.sourceforge.net"
+
+SLOT="0"
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="ncurses static-libs"
+
+RDEPEND="ncurses? ( sys-libs/ncurses )"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS NEWS README ChangeLog )
+
+src_prepare() {
+	sed -e "/^docdir/d" -i doc/Makefile.am || die
+	sed -e '/^dochdrdir/{s:$(prefix)/doc/@PACKAGE@:$(docdir):}' \
+		-i doc/headers/Makefile.am || die
+	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.in || die
+	eautoreconf
+	append-cppflags -D_BSD_SOURCE
+	append-libs $($(tc-getPKG_CONFIG) --libs ncurses)
+}
+
+src_configure() {
+	econf \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable static-libs static) \
+		--disable-debug \
+		$(use_enable ncurses curses)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}