1 files changed, 70 insertions, 0 deletions
diff --git a/dev-util/idea-community/idea-community-2018.3.1.183.4588.61-r1.ebuild b/dev-util/idea-community/idea-community-2018.3.1.183.4588.61-r1.ebuild
new file mode 100644
index 000000000000..c3da3d3edc20
--- /dev/null
+++ b/dev-util/idea-community/idea-community-2018.3.1.183.4588.61-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils versionator
+
+SLOT="0"
+PV_STRING="$(get_version_component_range 4-6)"
+MY_PV="$(get_version_component_range 1-3)"
+MY_PN="idea"
+
+# distinguish settings for official stable releases and EAP-version releases
+if [[ "$(get_version_component_range 7)x" = "prex" ]]
+then
+	# upstream EAP
+	KEYWORDS=""
+	SRC_URI="https://download.jetbrains.com/idea/${MY_PN}IC-${PV_STRING}.tar.gz"
+else
+	# upstream stable
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://download.jetbrains.com/idea/${MY_PN}IC-${MY_PV}.tar.gz -> ${MY_PN}IC-${PV_STRING}.tar.gz"
+fi
+
+DESCRIPTION="A complete toolset for web, mobile and enterprise development"
+HOMEPAGE="https://www.jetbrains.com/idea"
+
+LICENSE="Apache-2.0
+	custom-jdk? ( GPL-2 )"
+IUSE="-custom-jdk"
+
+DEPEND="!dev-util/${PN}:14
+	!dev-util/${PN}:15"
+RDEPEND="${DEPEND}
+	>=virtual/jdk-1.7:*"
+S="${WORKDIR}/${MY_PN}-IC-${PV_STRING}"
+
+QA_PREBUILT="opt/${PN}-${MY_PV}/*"
+
+src_prepare() {
+	if ! use arm; then
+		rm bin/fsnotifier-arm || die
+	fi
+	if ! use custom-jdk; then
+		if [[ -d jre ]]; then
+			rm -r jre || die
+		fi
+	fi
+}
+
+src_install() {
+	local dir="/opt/${PN}-${MY_PV}"
+
+	insinto "${dir}"
+	doins -r *
+	fperms 755 "${dir}"/bin/{idea.sh,fsnotifier{,64}}
+
+	if use custom-jdk; then
+		if [[ -d jre ]]; then
+		fperms 755 "${dir}"/jre/jre/bin/{java,jjs,keytool,orbd,pack200,policytool,rmid,rmiregistry,servertool,tnameserv,unpack200}
+		fi
+	fi
+
+	make_wrapper "${PN}" "${dir}/bin/${MY_PN}.sh"
+	newicon "bin/${MY_PN}.png" "${PN}.png"
+	make_desktop_entry "${PN}" "IntelliJ Idea Community" "${PN}" "Development;IDE;"
+
+	# recommended by: https://confluence.jetbrains.com/display/IDEADEV/Inotify+Watches+Limit
+	mkdir -p "${D}/etc/sysctl.d/" || die
+	echo "fs.inotify.max_user_watches = 524288" > "${D}/etc/sysctl.d/30-idea-inotify-watches.conf" || die
+}