1 files changed, 40 insertions, 0 deletions
diff --git a/media-libs/libvorbis/libvorbis-1.3.5.ebuild b/media-libs/libvorbis/libvorbis-1.3.5.ebuild
new file mode 100644
index 000000000000..af171b707f52
--- /dev/null
+++ b/media-libs/libvorbis/libvorbis-1.3.5.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+AUTOTOOLS_AUTORECONF=1
+inherit autotools-multilib
+
+DESCRIPTION="The Ogg Vorbis sound file format library"
+HOMEPAGE="http://xiph.org/vorbis"
+SRC_URI="http://downloads.xiph.org/releases/vorbis/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+
+RDEPEND=">=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
+	abi_x86_32? ( !app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
+
+src_prepare() {
+	sed -i \
+		-e '/CFLAGS/s:-O20::' \
+		-e '/CFLAGS/s:-mcpu=750::' \
+		configure.ac || die
+
+	# Un-hack docdir redefinition.
+	find -name 'Makefile.am' \
+		-exec sed -i \
+			-e 's:$(datadir)/doc/$(PACKAGE)-$(VERSION):@docdir@/html:' \
+			{} + || die
+
+	AT_M4DIR="m4" \
+	autotools-multilib_src_prepare
+}