1 files changed, 77 insertions, 0 deletions
diff --git a/media-sound/picard/picard-2.0.0_beta1.ebuild b/media-sound/picard/picard-2.0.0_beta1.ebuild
new file mode 100644
index 000000000000..504aadd08a1e
--- /dev/null
+++ b/media-sound/picard/picard-2.0.0_beta1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6} )
+DISTUTILS_SINGLE_IMPL=1
+DISABLE_AUTOFORMATTING=true
+
+inherit distutils-r1 readme.gentoo-r1 xdg-utils
+
+DESCRIPTION="A cross-platform music tagger"
+HOMEPAGE="https://picard.musicbrainz.org"
+SRC_URI="https://github.com/metabrainz/${PN}/archive/${PV/_beta1/.dev4}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="
+	dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_USEDEP}]
+	dev-qt/qtgui:5[accessibility]
+	>=media-libs/mutagen-1.38"
+DEPEND="
+	nls? ( dev-qt/linguist-tools:5 )
+"
+
+RESTRICT="test" # doesn't work with ebuilds
+
+# upstream quickly renamed to dev4 after buildsystem and runtime(!) were broken by 'beta1'
+S="${WORKDIR}/${P/_beta1/.dev4}"
+
+python_compile() {
+	local build_args=(
+		--disable-autoupdate
+	)
+	if ! use nls; then
+		build_args+=( --disable-locales )
+	fi
+	distutils-r1_python_compile ${build_args[@]}
+}
+
+python_install() {
+	local install_args=(
+		--disable-autoupdate
+		--skip-build
+	)
+	if ! use nls; then
+		install_args+=( --disable-locales )
+	fi
+	distutils-r1_python_install ${install_args[@]}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	local DOC_CONTENTS="Install optional package media-libs/chromaprint[tools] to enable
+calculation and lookup of AcoustID fingerprints.
+
+Install optional package dev-python/python-discid to enable
+calculation and lookup of compact disc identifiers (disc IDs).
+
+If you are upgrading Picard and it does not start, try removing
+Picard's settings:
+	rm ~/.config/MusicBrainz/Picard.conf"
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}