1 files changed, 55 insertions, 0 deletions
diff --git a/net-irc/scrollz/scrollz-2.1.ebuild b/net-irc/scrollz/scrollz-2.1.ebuild
new file mode 100644
index 000000000000..ae5876d3b7a4
--- /dev/null
+++ b/net-irc/scrollz/scrollz-2.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+DESCRIPTION="Advanced IRC client based on ircII"
+HOMEPAGE="http://packages.qa.debian.org/s/scrollz.html"
+SRC_URI="mirror://debian/pool/main/s/${PN}/${PN}_${PV}.orig.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86"
+IUSE="gmp gnutls ipv6 socks5 ssl"
+
+REQUIRED_USE="gnutls? ( ssl )"
+
+RDEPEND="sys-libs/ncurses
+	gmp? ( dev-libs/gmp )
+	ssl? (
+		gnutls? ( net-libs/gnutls )
+		!gnutls? ( dev-libs/openssl )
+		)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${P}.orig
+
+src_configure() {
+	local _myssl
+
+	if use ssl; then
+		if use gnutls; then
+			_myssl="--with-ssl"
+		else
+			_myssl="--with-openssl"
+		fi
+	fi
+
+	econf \
+		--with-default-server=irc.gentoo.org \
+		$(use_enable socks5) \
+		$(use_enable ipv6) \
+		--enable-regexp \
+		$(use_enable gmp fish) \
+		${_myssl}
+}
+
+src_install() {
+	einstall \
+		sharedir="${ED}/usr/share" \
+		mandir="${ED}/usr/share/man/man1"
+
+	dodoc ChangeLog* NEWS README* todo
+}