1 files changed, 49 insertions, 0 deletions
diff --git a/sci-geosciences/liblas/liblas-1.8.1.ebuild b/sci-geosciences/liblas/liblas-1.8.1.ebuild
new file mode 100644
index 000000000000..974af92e1f5d
--- /dev/null
+++ b/sci-geosciences/liblas/liblas-1.8.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="C/C++ library for manipulating the LAS LiDAR format common in GIS"
+HOMEPAGE="http://www.liblas.org"
+SRC_URI="http://download.osgeo.org/${PN}/libLAS-${PV}.tar.bz2"
+
+# tests known to fail due to LD_LIBRARY_PATH issue
+RESTRICT="test"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="gdal"
+
+RDEPEND="
+	dev-libs/boost:=
+	sci-geosciences/laszip
+	sci-libs/libgeotiff
+	gdal? ( sci-libs/gdal )
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/libLAS-${PV}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.0_remove-std-c++98.patch
+)
+
+src_prepare() {
+	default
+
+	# add missing linkage
+	sed -e 's:${LAS2COL} ${LIBLAS_C_LIB_NAME}:& ${CMAKE_THREAD_LIBS_INIT}:' \
+		-i "${S}/apps/CMakeLists.txt" || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DWITH_GDAL=$(usex gdal)"
+		-DLIBLAS_LIB_SUBDIR=$(get_libdir)
+	)
+	cmake-utils_src_configure
+}