1 files changed, 46 insertions, 0 deletions
diff --git a/sci-libs/libpdb/libpdb-991112.ebuild b/sci-libs/libpdb/libpdb-991112.ebuild
new file mode 100644
index 000000000000..9b1ce441b74b
--- /dev/null
+++ b/sci-libs/libpdb/libpdb-991112.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="3"
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="PDB Record I/O Libraries -- c version"
+HOMEPAGE="http://www.cgl.ucsf.edu/Overview/software.html"
+SRC_URI="mirror://gentoo/${P}.shar"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="BSD"
+IUSE=""
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	app-arch/sharutils"
+
+S="${WORKDIR}"/${PN}
+
+src_unpack() {
+	"${EPREFIX}"/usr/bin/unshar "${DISTDIR}"/${A} || die
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PV}-dynlib.patch
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS} -fPIC" \
+		${PN}.a || die
+}
+
+src_install() {
+	dolib.a ${PN}.a || die
+	dolib.so ${PN}.so.0.1 || die
+	dosym ${PN}.so.0.1 /usr/$(get_libdir)/${PN}.so.0
+	dosym ${PN}.so.0.1 /usr/$(get_libdir)/${PN}.so
+	insinto /usr/include/${PN}
+	doins *.h || die
+}