1 files changed, 46 insertions, 0 deletions
diff --git a/sys-apps/grep/grep-2.28.ebuild b/sys-apps/grep/grep-2.28.ebuild
new file mode 100644
index 000000000000..f2035a7b7ae3
--- /dev/null
+++ b/sys-apps/grep/grep-2.28.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="GNU regular expression matcher"
+HOMEPAGE="https://www.gnu.org/software/grep/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
+	mirror://gentoo/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="nls pcre static"
+
+LIB_DEPEND="pcre? ( >=dev-libs/libpcre-7.8-r1[static-libs(+)] )"
+RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
+	nls? ( virtual/libintl )
+	virtual/libiconv"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	static? ( ${LIB_DEPEND} )"
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+
+src_prepare() {
+	sed -i \
+		-e "s:@SHELL@:${EPREFIX}/bin/sh:g" \
+		src/egrep.sh || die #523898
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	# Always use pkg-config to get lib info for pcre.
+	export ac_cv_search_pcre_compile=$(
+		usex pcre "$($(tc-getPKG_CONFIG) --libs $(usex static --static '') libpcre)" ''
+	)
+	econf \
+		--bindir="${EPREFIX}"/bin \
+		$(use_enable nls) \
+		$(use_enable pcre perl-regexp)
+}