1 files changed, 47 insertions, 0 deletions
diff --git a/xfce-base/libxfce4util/libxfce4util-4.16.0.ebuild b/xfce-base/libxfce4util/libxfce4util-4.16.0.ebuild
new file mode 100644
index 000000000000..de84c2ad3ba2
--- /dev/null
+++ b/xfce-base/libxfce4util/libxfce4util-4.16.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit vala
+
+DESCRIPTION="A basic utility library for the Xfce desktop environment"
+HOMEPAGE="https://git.xfce.org/xfce/libxfce4util/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0/7"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
+IUSE="introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND=">=dev-libs/glib-2.50
+	introspection? ( dev-libs/gobject-introspection:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/intltool
+	dev-util/gtk-doc-am
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable vala)
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}