blob: 43a574817df7cb565da30b7d7706db30d5f5e46d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit go-module
EGIT_COMMIT="7b5f7e0d8f705ed4e54f7040512327e231433366"
DESCRIPTION="Docker-compatible CLI for containerd, with support for Compose"
HOMEPAGE="https://github.com/containerd/nerdctl"
SRC_URI="
https://github.com/containerd/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
https://github.com/containerd/${PN}/releases/download/v${PV}/${P}-go-mod-vendor.tar.gz
"
LICENSE="Apache-2.0"
LICENSE+=" BSD BSD-2 ISC MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="rootless"
DEPEND="
rootless? (
app-containers/slirp4netns
sys-apps/rootlesskit
)
"
RDEPEND="${DEPEND}"
src_unpack() {
unpack "${P}.tar.gz"
cd "${S}"
unpack "${P}-go-mod-vendor.tar.gz"
}
src_compile() {
emake VERSION=v${PV} REVISION="${EGIT_COMMIT}"
}
src_install() {
local emake_args=(
DESTDIR="${D}"
VERSION=v${PV}
REVISION="${EGIT_COMMIT}"
DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
PREFIX="${EPREFIX}/usr"
install
)
emake "${emake_args[@]}"
DOCS=( README.md docs/* examples )
einstalldocs
}
|
GitWeb
