app-emulation/ski/ski-1.4.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit flag-o-matic

DESCRIPTION="ia64 instruction set simulator"
HOMEPAGE="https://github.com/trofi/ski http://ski.sourceforge.net/"
SRC_URI="https://github.com/trofi/ski/releases/download/v${PV}/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug motif"

RDEPEND="
	dev-libs/libltdl:=
	sys-libs/ncurses:=
	virtual/libelf
	debug? ( sys-libs/binutils-libs:= )
	motif? ( x11-libs/motif:= )
"
DEPEND="
	${RDEPEND}
	dev-util/gperf
"
# games-sports/ski and app-emulation/ski both install 'ski' binary, bug #653110
RDEPEND="
	${RDEPEND}
	!games-sports/ski
"

src_configure() {
	# bug #854531
	filter-lto

	local myeconfargs=(
		--without-gtk
		$(use_with motif x11)
		$(use_with debug bfd)
	)

	econf "${myeconfargs[@]}"
}