dev-ml/jbuilder/jbuilder-1.0_beta11.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=5

MY_PV="${PV/_/+}"
MY_P="${PN}-${PV/_/-}"

DESCRIPTION="A composable build system for OCaml"
HOMEPAGE="https://github.com/janestreet/jbuilder"
SRC_URI="https://github.com/janestreet/jbuilder/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc"
IUSE="test"

DEPEND="dev-lang/ocaml:="
RDEPEND="${DEPEND}"
DEPEND="${DEPEND}
	dev-ml/opam
	test? ( dev-ml/menhir )
"
OPAMSWITCH="system"

S="${WORKDIR}/${MY_P}"
OPAMROOT="${D}"

src_prepare() {
	# Disable Werror like behavior, doesnt build with ocaml 4.05 otherwise
	sed -i -e 's/--dev//' Makefile || die
}

src_install() {
	opam-installer -i \
		--prefix="${ED}/usr" \
		--libdir="${D}/$(ocamlc -where)" \
		--docdir="${ED}/usr/share/doc/${PF}" \
		--mandir="${ED}/usr/share/man" \
		${PN}.install || die
}