blob: 74552c0cc1914cb9562df8279a6f8b704a0a6f76 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} pypy3 )
inherit distutils-r1
DESCRIPTION="A goodie-bag of unix shell and environment tools for py.test"
HOMEPAGE="
https://github.com/man-group/pytest-plugins/
https://pypi.org/project/pytest-shutil/
"
SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
RDEPEND="
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
dev-python/execnet[${PYTHON_USEDEP}]
dev-python/path-py[${PYTHON_USEDEP}]
dev-python/mock[${PYTHON_USEDEP}]
dev-python/termcolor[${PYTHON_USEDEP}]
"
# block pytest plugins that will be broken by the upgrade
RDEPEND+="
!<dev-python/pytest-virtualenv-1.7.0-r1[python_targets_python2_7(-)]
"
BDEPEND="
${RDEPEND}
dev-python/setuptools-git[${PYTHON_USEDEP}]
"
distutils_enable_tests pytest
python_prepare_all() {
# remove unnecessary deps
# (contextlib2 is not used in py3)
sed -i -e '/path\.py/d' -e '/contextlib2/d' setup.py || die
distutils-r1_python_prepare_all
}
|
GitWeb
