blob: 1d092396800fb14f818302f1a99217d9f4b34e96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
# setup.py is written only for py2, which suits pypy
PYTHON_COMPAT=( python2_7 pypy )
inherit distutils-r1 multilib
DESCRIPTION="Various LDAP-related Python modules"
HOMEPAGE="http://www.python-ldap.org https://pypi.python.org/pypi/python-ldap"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="PSF-2"
SLOT="0"
KEYWORDS="alpha amd64 hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd ~x86-solaris"
# doc flag dropped due to absence of the docs
IUSE="examples sasl ssl"
# If you need support for openldap-2.3.x, please use python-ldap-2.3.9.
# python team: Please do not remove python-ldap-2.3.9 from the tree.
# OpenSSL is an optional runtime dep.
RDEPEND=">net-nds/openldap-2.4.11
dev-python/pyasn1[${PYTHON_USEDEP}]
sasl? ( >=dev-libs/cyrus-sasl-2.1 )"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]"
python_prepare_all() {
sed -e "s:^library_dirs =.*:library_dirs = /usr/$(get_libdir) /usr/$(get_libdir)/sasl2:" \
-e "s:^include_dirs =.*:include_dirs = ${EPREFIX}/usr/include ${EPREFIX}/usr/include/sasl:" \
-i setup.cfg || die "error fixing setup.cfg"
local mylibs="ldap"
if use sasl; then
use ssl && mylibs="ldap_r"
mylibs="${mylibs} sasl2"
else
sed -e 's/HAVE_SASL//g' -i setup.cfg || die
fi
use ssl && mylibs="${mylibs} ssl crypto"
use elibc_glibc && mylibs="${mylibs} resolv"
sed -e "s:^libs = .*:libs = lber ${mylibs}:" \
-i setup.cfg || die "error setting up libs in setup.cfg"
# set test expected to fail to expectedFailure
sed -e "s:^ def test_bad_urls: @unittest.expectedFailure\n def test_bad_urls:" \
-i Tests/t_ldapurl.py || die
distutils-r1_python_prepare_all
}
python_test() {
# XXX: the tests supposedly can start local slapd
# but it requires some manual config, it seems.
"${PYTHON}" Tests/t_ldapurl.py || die "Tests fail with ${EPYTHON}"
}
python_install_all() {
use examples && local EXAMPLES=( Demo/. )
distutils-r1_python_install_all
}
|
GitWeb
