blob: 78a304867d748ae6efd2cdbeaf932d28b9512a93 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=flit
PYTHON_COMPAT=( pypy3 python3_{10..13} )
inherit distutils-r1 pypi
DESCRIPTION="Style preserving TOML library"
HOMEPAGE="
https://github.com/python-poetry/tomlkit/
https://pypi.org/project/tomlkit/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
BDEPEND="
test? (
dev-python/pyyaml[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
PATCHES=(
# https://github.com/python-poetry/tomlkit/pull/349
"${FILESDIR}/${P}-py313.patch"
)
src_configure() {
grep -q 'build-backend = "poetry' pyproject.toml ||
die "Upstream changed build-backend, recheck"
# write a custom pyproject.toml to ease setuptools bootstrap
cat > pyproject.toml <<-EOF || die
[build-system]
requires = ["flit_core >=3.2,<4"]
build-backend = "flit_core.buildapi"
[project]
name = "tomlkit"
version = "${PV}"
description = "Style preserving TOML library"
EOF
}
python_test() {
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest
}
|
GitWeb
