games-emulation/dosbox-staging/dosbox-staging-0.75.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit autotools desktop

DESCRIPTION="Modernized DOSBox soft-fork"
HOMEPAGE="https://dosbox-staging.github.io/"
SRC_URI="https://github.com/dosbox-staging/dosbox-staging/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa debug dynrec network opengl opus"

RDEPEND="alsa? ( media-libs/alsa-lib )
	debug? ( sys-libs/ncurses:0= )
	network? ( media-libs/sdl2-net )
	opengl? ( virtual/opengl )
	opus? ( media-libs/opusfile )
	media-libs/libpng:0=
	media-libs/libsdl2[joystick,opengl?,video,X]
	sys-libs/zlib
	!games-emulation/dosbox"
DEPEND="${RDEPEND}"
BDEPEND=""

PATCHES=( "${FILESDIR}"/${P}-pthread.patch )

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable alsa alsa-midi) \
		$(use_enable debug) \
		$(use_enable !dynrec dynamic-x86) \
		$(use_enable dynrec) \
		$(use_enable network) \
		$(use_enable opengl) \
		$(use_enable opus opus-cdda)
}

src_install() {
	default
	doicon contrib/icons/${PN}.svg
	make_desktop_entry dosbox DOSBox-staging ${PN}
}