blob: f42ddb8941af9edab76eb75f678619fb365a95a2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
LUA_COMPAT=( luajit )
PYTHON_COMPAT=( python3_{8..10} )
inherit cmake lua-single python-single-r1 xdg
OBS_BROWSER_COMMIT="b798763ae75b538e405c2d7e2ab3a1edfe59ed0c"
CEF_DIR="cef_binary_4638_linux64"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git"
EGIT_SUBMODULES=( plugins/obs-browser )
else
SRC_URI="https://github.com/obsproject/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" browser? ( https://github.com/obsproject/obs-browser/archive/${OBS_BROWSER_COMMIT}.tar.gz -> obs-browser-${OBS_BROWSER_COMMIT}.tar.gz )"
KEYWORDS="~amd64 ~ppc64 ~x86"
fi
SRC_URI+=" browser? ( https://cdn-fastly.obsproject.com/downloads/${CEF_DIR}.tar.bz2 )"
DESCRIPTION="Software for Recording and Streaming Live Video Content"
HOMEPAGE="https://obsproject.com"
LICENSE="GPL-2"
SLOT="0"
IUSE="
+alsa browser decklink fdk jack lua nvenc pipewire
pulseaudio python speex +ssl truetype v4l vlc wayland
"
REQUIRED_USE="
browser? ( || ( alsa pulseaudio ) )
lua? ( ${LUA_REQUIRED_USE} )
python? ( ${PYTHON_REQUIRED_USE} )
"
BDEPEND="
lua? ( dev-lang/swig )
python? ( dev-lang/swig )
"
DEPEND="
dev-libs/glib:2
dev-libs/jansson:=
dev-qt/qtcore:5
dev-qt/qtgui:5[wayland?]
dev-qt/qtnetwork:5
dev-qt/qtquickcontrols:5
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
media-libs/libglvnd
media-libs/x264:=
media-video/ffmpeg:=[nvenc?,x264]
net-misc/curl
sys-apps/dbus
sys-apps/pciutils
sys-libs/zlib:=
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXfixes
x11-libs/libxcb:=
alsa? ( media-libs/alsa-lib )
browser? (
app-accessibility/at-spi2-atk
app-accessibility/at-spi2-core:2
dev-libs/atk
dev-libs/expat
dev-libs/glib
dev-libs/nspr
dev-libs/nss
media-libs/alsa-lib
media-libs/fontconfig
media-libs/mesa[gbm(+)]
net-print/cups
x11-libs/cairo
x11-libs/libdrm
x11-libs/libXcursor
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXi
x11-libs/libxkbcommon
x11-libs/libXrandr
x11-libs/libXrender
x11-libs/libXScrnSaver
x11-libs/libxshmfence
x11-libs/libXtst
x11-libs/pango
)
fdk? ( media-libs/fdk-aac:= )
jack? ( virtual/jack )
lua? ( ${LUA_DEPS} )
pipewire? ( media-video/pipewire:= )
pulseaudio? ( media-sound/pulseaudio )
python? ( ${PYTHON_DEPS} )
speex? ( media-libs/speexdsp )
ssl? ( net-libs/mbedtls:= )
truetype? (
media-libs/fontconfig
media-libs/freetype
)
v4l? (
media-libs/libv4l
virtual/udev
)
vlc? ( media-video/vlc:= )
wayland? (
dev-libs/wayland
x11-libs/libxkbcommon
)
"
RDEPEND="${DEPEND}"
QA_PREBUILT="
usr/lib*/obs-plugins/chrome-sandbox
usr/lib*/obs-plugins/libcef.so
usr/lib*/obs-plugins/libEGL.so
usr/lib*/obs-plugins/libGLESv2.so
usr/lib*/obs-plugins/libvk_swiftshader.so
usr/lib*/obs-plugins/libvulkan.so.1
usr/lib*/obs-plugins/swiftshader/libEGL.so
usr/lib*/obs-plugins/swiftshader/libGLESv2.so
"
pkg_setup() {
use lua && lua-single_pkg_setup
use python && python-single-r1_pkg_setup
}
src_unpack() {
default
if [[ ${PV} == 9999 ]]; then
git-r3_src_unpack
elif use browser; then
rm -d ${P}/plugins/obs-browser || die
mv obs-browser-${OBS_BROWSER_COMMIT} ${P}/plugins/obs-browser || die
fi
}
src_prepare() {
# We have not enabled VST before, but now it will be looked for unconditionally if
# any plugins are enabled, so make the VST part a warning instead of fatal for now.
sed -i 's/FATAL_ERROR "obs-vst submodule not available/WARNING "obs-vst submodule not available/' \
plugins/CMakeLists.txt || die
cmake_src_prepare
}
src_configure() {
local libdir=$(get_libdir)
local mycmakeargs=(
$(usev browser -DCEF_ROOT_DIR=../${CEF_DIR})
-DENABLE_ALSA=$(usex alsa)
-DENABLE_AJA=OFF
-DENABLE_BROWSER=$(usex browser)
-DENABLE_DECKLINK=$(usex decklink)
-DENABLE_FREETYPE=$(usex truetype)
-DENABLE_JACK=$(usex jack)
-DENABLE_LIBFDK=$(usex fdk)
-DENABLE_PIPEWIRE=$(usex pipewire)
-DENABLE_PULSEAUDIO=$(usex pulseaudio)
-DENABLE_RTMPS=$(usex ssl ON OFF)
-DENABLE_SPEEXDSP=$(usex speex)
-DENABLE_V4L2=$(usex v4l)
-DENABLE_VLC=$(usex vlc)
-DENABLE_WAYLAND=$(usex wayland)
-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
-DUNIX_STRUCTURE=1
)
if [[ ${PV} != 9999 ]]; then
mycmakeargs+=(
-DOBS_VERSION_OVERRIDE=${PV}
)
fi
if use lua || use python; then
mycmakeargs+=(
-DENABLE_SCRIPTING_LUA=$(usex lua)
-DENABLE_SCRIPTING_PYTHON=$(usex python)
-DENABLE_SCRIPTING=ON
)
else
mycmakeargs+=( -DENABLE_SCRIPTING=OFF )
fi
cmake_src_configure
}
src_install() {
cmake_src_install
# external plugins may need some things not installed by default, install them here
insinto /usr/include/obs/UI/obs-frontend-api
doins UI/obs-frontend-api/obs-frontend-api.h
}
pkg_postinst() {
xdg_pkg_postinst
if ! use alsa && ! use pulseaudio; then
elog
elog "For the audio capture features to be available,"
elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
elog "be enabled."
elog
fi
}
|
GitWeb