blob: 041e5c27e526d6678ce6b344241d5465bdffe926 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit systemd toolchain-funcs
DESCRIPTION="Prosody is a flexible communications server for Jabber/XMPP written in Lua"
HOMEPAGE="https://prosody.im/"
SRC_URI="https://prosody.im/downloads/source/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="libevent libressl luajit mysql postgres sqlite ssl test zlib"
RESTRICT="!test? ( test )"
COMMON_DEPEND="
dev-lua/LuaBitOp
net-dns/libidn
net-im/jabber-base
libressl? ( dev-libs/libressl:= )
!libressl? ( dev-libs/openssl:0= )
luajit? ( dev-lang/luajit:2 )
!luajit? ( dev-lang/lua:0 )
"
DEPEND="
${COMMON_DEPEND}
test? ( dev-lua/busted )
"
RDEPEND="
${COMMON_DEPEND}
~dev-lua/luaexpat-1.3.0
dev-lua/luafilesystem
dev-lua/luasocket
libevent? ( dev-lua/luaevent )
mysql? ( dev-lua/luadbi[mysql] )
postgres? ( dev-lua/luadbi[postgres] )
sqlite? ( dev-lua/luadbi[sqlite] )
ssl? ( dev-lua/luasec )
zlib? ( dev-lua/lua-zlib )
"
PATCHES=( "${FILESDIR}/${PN}-0.11.2-r1-gentoo.patch" )
src_configure() {
local myeconfargs=(
--c-compiler="$(tc-getCC)"
--datadir="${EPREFIX}/var/spool/jabber"
--libdir="${EPREFIX}/usr/$(get_libdir)"
--linker="$(tc-getCC)"
--ostype="linux"
--prefix="${EPREFIX}/usr"
--runwith="$(usex luajit luajit lua)"
--sysconfdir="${EPREFIX}/etc/jabber"
--with-lua-include="${EPREFIX}/usr/include"
--with-lua-lib="${EPREFIX}/usr/$(get_libdir)/lua"
)
# Since the configure script is handcrafted,
# and yells at unknown options, do not use 'econf'.
./configure ${myeconfargs[@]} --cflags="${CFLAGS} -Wall -fPIC" --ldflags="${LDFLAGS} -shared" || die
rm makefile || die
mv GNUmakefile Makefile || die
}
src_install() {
emake DESTDIR="${D}" install
keepdir /var/spool/jabber
newinitd "${FILESDIR}"/prosody.initd-r3 prosody
systemd_dounit "${FILESDIR}"/prosody.service
systemd_newtmpfilesd "${FILESDIR}"/prosody.tmpfilesd prosody.conf
}
|
GitWeb