blob: 543cabf61d5c384738777c1f637e12dbc202ae88 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit git-r3 tmpfiles systemd toolchain-funcs
DESCRIPTION="NTP client and server programs"
HOMEPAGE="https://chrony.tuxfamily.org/"
EGIT_REPO_URI="https://git.tuxfamily.org/chrony/chrony.git/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="
+adns +caps +cmdmon html ipv6 libedit +ntp +phc pps readline +refclock +rtc
+seccomp selinux
"
REQUIRED_USE="
?? ( libedit readline )
"
CDEPEND="
caps? ( sys-libs/libcap )
libedit? ( dev-libs/libedit )
readline? ( >=sys-libs/readline-4.1-r4:= )
seccomp? ( sys-libs/libseccomp )
"
DEPEND="
${CDEPEND}
caps? ( acct-group/ntp acct-user/ntp )
dev-ruby/asciidoctor
pps? ( net-misc/pps-tools )
"
RDEPEND="
${CDEPEND}
selinux? ( sec-policy/selinux-chronyd )
"
RESTRICT=test
S="${WORKDIR}/${P/_/-}"
PATCHES=(
"${FILESDIR}"/${PN}-3.5-pool-vendor-gentoo.patch
"${FILESDIR}"/${PN}-3.5-r3-systemd-gentoo.patch
)
src_prepare() {
default
sed -i \
-e 's:/etc/chrony\.conf:/etc/chrony/chrony.conf:g' \
doc/* examples/* || die
# Copy for potential user fixup
cp "${FILESDIR}"/chronyd.conf "${T}"/chronyd.conf
cp examples/chronyd.service "${T}"/chronyd.service
# Set config for privdrop
if ! use caps; then
sed -i \
-e 's/-u ntp//' \
"${T}"/chronyd.conf "${T}"/chronyd.service || die
fi
if ! use seccomp; then
sed -i \
-e 's/-F 1//' \
"${T}"/chronyd.conf "${T}"/chronyd.service || die
fi
}
src_configure() {
tc-export CC
local CHRONY_EDITLINE
# ./configure legend:
# --disable-readline : disable line editing entirely
# --without-readline : do not use sys-libs/readline (enabled by default)
# --without-editline : do not use dev-libs/libedit (enabled by default)
if ! use readline && ! use libedit; then
CHRONY_EDITLINE='--disable-readline'
else
CHRONY_EDITLINE+=" $(usex readline '' --without-readline)"
CHRONY_EDITLINE+=" $(usex libedit '' --without-editline)"
fi
# not an autotools generated script
local myconf=(
$(use_enable seccomp scfilter)
$(usex adns '' --disable-asyncdns)
$(usex caps '' --disable-linuxcaps)
$(usex cmdmon '' --disable-cmdmon)
$(usex ipv6 '' --disable-ipv6)
$(usex ntp '' --disable-ntp)
$(usex phc '' --disable-phc)
$(usex pps '' --disable-pps)
$(usex refclock '' --disable-refclock)
$(usex rtc '' --disable-rtc)
${CHRONY_EDITLINE}
${EXTRA_ECONF}
--chronysockdir="${EPREFIX}/run/chrony"
--disable-sechash
--docdir="${EPREFIX}/usr/share/doc/${PF}"
--mandir="${EPREFIX}/usr/share/man"
--prefix="${EPREFIX}/usr"
--sysconfdir="${EPREFIX}/etc/chrony"
--with-pidfile="${EPREFIX}/run/chrony/chronyd.pid"
--without-nss
--without-tomcrypt
)
# print the ./configure call to aid in future debugging
echo bash ./configure "${myconf[@]}" >&2
bash ./configure "${myconf[@]}" || die
}
src_compile() {
emake all docs
}
src_install() {
default
newinitd "${FILESDIR}"/chronyd.init-r2 chronyd
newconfd "${T}"/chronyd.conf chronyd
insinto /etc/${PN}
newins examples/chrony.conf.example1 chrony.conf
docinto examples
dodoc examples/*.example*
newtmpfiles - chronyd.conf <<<"d /run/chrony 0750 $(usex caps 'ntp ntp' 'root root')"
docinto html
dodoc doc/*.html
keepdir /var/{lib,log}/chrony
insinto /etc/logrotate.d
newins "${FILESDIR}"/chrony-2.4-r1.logrotate chrony
systemd_dounit "${T}"/chronyd.service
systemd_dounit examples/chrony-wait.service
systemd_enable_ntpunit 50-chrony chronyd.service
}
pkg_postinst() {
tmpfiles_process chronyd.conf
}
|
GitWeb