blob: 1c422cf550fa2c12dcfbd4392ee05465d8add652 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
inherit distutils-r1
DESCRIPTION="Utility to manage SSH public keys stored in LDAP"
HOMEPAGE="https://github.com/jirutka/ssh-ldap-pubkey"
if [[ ${PV} == "9999" ]]; then
EGIT_REPO_URI="https://github.com/jirutka/${PN}/${PN}.git"
inherit git-r3
else
SRC_URI="https://github.com/jirutka/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~ppc64 ~x86"
fi
LICENSE="MIT"
SLOT="0"
IUSE="test"
RESTRICT="!test? ( test )"
MY_CDEPEND="
dev-python/docopt[${PYTHON_USEDEP}]
dev-python/pyldap[${PYTHON_USEDEP}]
virtual/logger"
DEPEND="
${MY_CDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/pytest-describe[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
)"
# We need to block previous net-misc/openssh packages
# to avoid file collision on "/etc/openldap/schema/openssh-lpk.schema"
RDEPEND="${MY_CDEPEND}
!net-misc/openssh[ldap]"
DOCS=( README.md CHANGELOG.adoc )
python_test() {
pytest -vv || die "Tests failed under ${EPYTHON}"
}
python_install_all() {
distutils-r1_python_install_all
insinto /etc/openldap/schema
doins etc/openssh-lpk.schema
local MY_DOCDIR="/usr/share/doc/${PF}/examples"
insinto "${MY_DOCDIR}"
doins etc/ldap.conf
# We don't want to compress this small file to allow user
# to diff configuration against upstream's default
docompress -x "${MY_DOCDIR}"
}
|
GitWeb
