blob: b2c2c5a39252168bc2c492184d7be6bae79deb53 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils git-r3 toolchain-funcs flag-o-matic
DEB_VER="3"
DESCRIPTION="Tool for creating compressed filesystem type squashfs"
HOMEPAGE="http://squashfs.sourceforge.net"
EGIT_REPO_URI="
https://git.kernel.org/pub/scm/fs/squashfs/squashfs-tools.git
"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="debug lz4 lzma lzo static xattr +xz"
LIB_DEPEND="sys-libs/zlib[static-libs(+)]
!xz? ( !lzo? ( sys-libs/zlib[static-libs(+)] ) )
lz4? ( app-arch/lz4[static-libs(+)] )
lzma? ( app-arch/xz-utils[static-libs(+)] )
lzo? ( dev-libs/lzo[static-libs(+)] )
xattr? ( sys-apps/attr[static-libs(+)] )
xz? ( app-arch/xz-utils[static-libs(+)] )"
RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )"
DEPEND="${RDEPEND}
static? ( ${LIB_DEPEND} )"
PATCHES=(
"${FILESDIR}"/${PN}-4.3-sysmacros.patch
"${FILESDIR}"/${PN}-4.3-aligned-data.patch
"${FILESDIR}"/${PN}-4.3-xattrs.patch
)
use10() { usex $1 1 0 ; }
src_configure() {
cd "${WORKDIR}"/${P}/${PN} || die
# set up make command line variables in EMAKE_SQUASHFS_CONF
EMAKE_SQUASHFS_CONF=(
LZMA_XZ_SUPPORT=$(use10 lzma)
LZO_SUPPORT=$(use10 lzo)
LZ4_SUPPORT=$(use10 lz4)
XATTR_SUPPORT=$(use10 xattr)
XZ_SUPPORT=$(use10 xz)
)
tc-export CC
use debug && append-cppflags -DSQUASHFS_TRACE
use static && append-ldflags -static
}
src_compile() {
cd "${WORKDIR}"/${P}/${PN} || die
emake "${EMAKE_SQUASHFS_CONF[@]}"
}
src_install() {
cd "${WORKDIR}"/${P}/${PN} || die
dobin mksquashfs unsquashfs
cd .. || die
dodoc CHANGES README RELEASE-README RELEASE-READMEs/*
}
|
GitWeb
