gopass: added bash/zsh completion, git snapshot and test useflags

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 50 insertions, 0 deletions

diff --git a/app-admin/gopass/gopass-9999.ebuild b/app-admin/gopass/gopass-9999.ebuild
new file mode 100644
index 0000000..014f262
--- /dev/null
+++ b/app-admin/gopass/gopass-9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit bash-completion-r1
+
+EGO_PN=github.com/justwatchcom/${PN}
+
+if [[ ${PV} == 9999 ]]; then
+	inherit golang-vcs
+else
+	KEYWORDS="~amd64 ~x86 ~arm"
+	EGIT_COMMIT="v${PV}"
+	SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	inherit golang-vcs-snapshot
+fi
+
+DESCRIPTION="The team password manager. Written in Go."
+HOMEPAGE="https://www.justwatch.com/gopass"
+LICENSE="MIT"
+SLOT="0"
+IUSE="X zsh-completion test"
+DEPEND=">=dev-lang/go-1.6:="
+RDEPEND="
+	app-crypt/gnupg
+	X? ( x11-misc/xclip )
+	zsh-completion? ( app-shells/gentoo-zsh-completions )
+	dev-vcs/git
+"
+
+src_compile() {
+	cd "${S}"/src/${EGO_PN} || die
+	GOPATH="${S}" LDFLAGS="" emake build || die
+}
+
+src_install() {
+	cd "${S}"/src/${EGO_PN} || die
+	emake DESTDIR="${D}" install
+	if use zsh-completion; then
+		emake zsh.completion || die
+		insinto /usr/share/zsh/site-functions
+		newins zsh.completion _${PN}
+	fi
+	emake bash.completion || die
+	newbashcomp bash.completion ${PN}
+	einstalldocs
+}
+