media-video/openshot: 2.5.1_p20201227 snapshot bump

Bug: https://bugs.gentoo.org/709858
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/media-video/openshot/openshot-2.5.1_p20201227.ebuild b/media-video/openshot/openshot-2.5.1_p20201227.ebuild
new file mode 100644
index 000000000000..97eb2a8c185e
--- /dev/null
+++ b/media-video/openshot/openshot-2.5.1_p20201227.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_REQ_USE=xml
+DISTUTILS_SINGLE_IMPL=1
+
+COMMIT=5056d240c5dff1a9191ca2e0f7a8813c57b5b5ca
+MY_PN="${PN}-qt"
+inherit distutils-r1 xdg
+
+DESCRIPTION="Award-winning free and open-source video editor"
+HOMEPAGE="https://www.openshot.org/"
+SRC_URI="https://github.com/OpenShot/${MY_PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${COMMIT}"
+
+LICENSE="GPL-3+"
+SLOT="1"
+# KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/httplib2[${PYTHON_MULTI_USEDEP}]
+		dev-python/PyQt5[${PYTHON_MULTI_USEDEP},gui,svg,widgets]
+		dev-python/PyQtWebEngine[${PYTHON_MULTI_USEDEP}]
+		dev-python/pyzmq[${PYTHON_MULTI_USEDEP}]
+		dev-python/requests[${PYTHON_MULTI_USEDEP}]
+	')
+	>=media-libs/libopenshot-0.2.5:0=[python,${PYTHON_SINGLE_USEDEP}]
+"
+BDEPEND="
+	$(python_gen_cond_dep '
+		doc? ( dev-python/sphinx[${PYTHON_MULTI_USEDEP}] )
+	')
+"
+
+src_prepare() {
+	distutils-r1_python_prepare_all
+	# prevent setup.py from trying to update MIME databases
+	sed -i 's/^ROOT =.*/ROOT = False/' setup.py || die
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+}