sys-kernel/gentoo-kernel-bin: bump to 5.11.6 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 450d37d28285..80151162e908 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -70,6 +70,7 @@ DIST gentoo-kernel-5.11.5-1.amd64.xpak 64924579 BLAKE2B b4484bb69d8355f63acecada
 DIST gentoo-kernel-5.11.5-1.arm64.xpak 59869818 BLAKE2B 26d4431d1e9e3dd58f1d352ab872cf2749d64ae768a114d42cf1bf3ac342c9792dfa19ccd1bf502ea26ee99a0bb00e75783b2958726d5073d8f69c3f66e29a9c SHA512 ea64669b86cb1a3c86f92016f8a9838eabf1328c9a996084c8e8226b736d526b7d246f42d24ff9d07d2d0606cc0db914251b7007caa74080a482c0bcdd4a0bc6
 DIST gentoo-kernel-5.11.5-1.x86.xpak 57891193 BLAKE2B f9f1eed75c7a81067994fe07a8305e5d70001c4ac969ae4d39d222960cf70c5fe5591db0a4e19fbaca9faa53e6dc1206158c0ad071cf3907761a61b00eedf098 SHA512 9494f10ae5a2ad3a0232e9eca5cb16647e4967f5ded3b45b5752f2e380b1c21437b9239d2fc7336cd84a246b488dc405e389c844263834a1feeea9257b2f8779
 DIST gentoo-kernel-5.11.6-1.amd64.xpak 64926961 BLAKE2B 3134919e40bd922dc334999c7b32d5810779c7833b2719ba0d5b2fb975afce70142faa3dd047c73f12384a74aa1eafd8e9900357feedb58dc8b074b563a61501 SHA512 fd4cfb53d2ca7c2a4869951c1dd9f32fe7878274d337b851b5dfd8fe3ab2bc7a0ec41164441ca49e0dbbde93dcfaa2969c1a60ae529b82c47ad7c1247be1b21c
+DIST gentoo-kernel-5.11.6-1.arm64.xpak 59948554 BLAKE2B bdc44a259d7c6a75a44e0d5606689eef1beae84fe9671cdb17e85eef35f059593d465b6538629c0713e3d2c3fd24bb5088339a43602525eb49187d839d5e6cc9 SHA512 60d7e099e605fb843e069d0bc217388e2f5aa847369cfbfa965f2fa81c5c34b6a47b02d9d0781aa55030d0138fff35c1062ae6198ff6625bcc49e7764ac7c823
 DIST gentoo-kernel-5.11.6-1.x86.xpak 57886583 BLAKE2B 6199bac90efa9c4d9db1b69151ddef53152406a8e8e3a67124dfef3abc4334ecfa387f70842c10751ff0b41efe9efdaa1aa0db675c86fb6b4f41f90ad597b3d4 SHA512 546185317fad3bac4e2908c9685b357cbdfd311ad4ff378b1d99c2b0212d4a5a68c8148efd48441647363d087d223a87ca2b7c8e6a4286513ca9eb9a74d44c72
 DIST gentoo-kernel-5.11.7-1.amd64.xpak 64458248 BLAKE2B 119a8440af915cd2b6040b6be0905614632bd6f99fd9f0d8cb3d3694e2a9720fd2b3623f5572441b570c1a46f1a3f49985a4c2f66107d327ad95761afcb6970d SHA512 4b03ee42ec8e25c286e85283026e3284509a689d1b91f1be3ec6312a8a85382a5718ca8f1c8708ec57118d2884bacf3d456c7448552390a98caefe16124afa4b
 DIST gentoo-kernel-5.11.7-1.x86.xpak 57450576 BLAKE2B bce3c47f76d16da2b6865a0f890d34ad6b4cc9fb0e129c7c458e1aa33e2110d8633d3279ce8b50e3d012acda8e219c574c9d952f98c2b773d0a8783224af5223 SHA512 76dcf77c7f46706c44f21e975cc96aa48037631ec4349e5dd15b9488fc28b299ddf75db2f2c2147f64a32eb37ed7682c553d0a6b9940a89c70e227a097d7f00b
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.6-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.6-r1.ebuild
new file mode 100644
index 000000000000..1d8f27f26279
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.6-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${PV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"usr/src/linux-${PV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${PV}"/ || die
+}