sys-power/thermald: version bump, 1.9

Closes: https://bugs.gentoo.org/697770
Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Yixun Lan <dlan@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/sys-power/thermald/thermald-1.9.ebuild b/sys-power/thermald/thermald-1.9.ebuild
new file mode 100644
index 000000000000..33bfe3ff73b1
--- /dev/null
+++ b/sys-power/thermald/thermald-1.9.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic out-of-source systemd
+
+DESCRIPTION="Thermal daemon for Intel architectures"
+HOMEPAGE="https://01.org/linux-thermal-daemon"
+SRC_URI="https://github.com/01org/thermal_daemon/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-libs/dbus-glib:=
+	dev-libs/glib:=
+	dev-libs/libxml2:=
+	sys-apps/dbus:="
+DEPEND="${RDEPEND}
+	dev-util/glib-utils"
+
+S=${WORKDIR}/thermal_daemon-${PV}
+DOCS=( thermal_daemon_usage.txt README.txt )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+my_src_configure() {
+	# bug 618948
+	append-cxxflags -std=c++14
+
+	ECONF_SOURCE="${S}" econf \
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+}
+
+my_src_install_all() {
+	einstalldocs
+
+	rm -rf "${ED%/}"/etc/init || die
+	doinitd "${FILESDIR}"/thermald
+}